手動で波を発生させるシミュレーション

coding UTF-8;

import GUI;
import Math;
import tool.Graph2D;


// ラインの頂点数
const int N = 1024;

// ラインの頂点の座標
float vertexX[N];
float vertexY[N];

// ラインの頂点の速度
float vertexVY[N];

// ラインの頂点に働く力
float vertexFY[N];


// 媒質の長さ
const float LENGTH = 10.0;

// 単位長さあたりの質量密度
const float DENSITY = 100.0;

// 張力
const float TENSION = 10.0;

// 減衰力係数
const float FRICTION = 0.03;

// スライダーの振幅
const float SLIDER_AMPLITUDE = 1.0;

// シミュレーションの時間刻み
const float DT = 0.01;

// 1フレームのアニメーションウェイト
const int WAIT = 20;

// グラフのIDを格納する変数
int graph;

// スライダーの値を保持する変数
float sliderValue = 0.0;

// メインループの継続/脱出を制御する変数
bool mainLoopState = true;

// 自由端かどうか
bool freeEnd = false;


/**
 * main関数、最初にシステムから呼び出されます。
 */
void main(){

	// 初期化処理
	initialize();

	// メインループへ
	mainLoop();

}


/**
 * メインループ部分です。
 */
void mainLoop(){

	// 描画を一定周期ごとに行うためのカウンタ
	int plotTiming = 50;
	int plotCounter = 0;

	// メインループ
	while(mainLoopState){

		// 状態の更新処理（力学シミュレーション）
		update();

		// plotTiming回に一回、グラフを描画する
		if(plotCounter == plotTiming){

			// 状態をグラフに描画
			setGraph2DData(graph, vertexX, vertexY);

			// 少し待機（アニメーションウェイト）
			sleep(WAIT);

			// 描画タイミングのカウンタをリセット
			plotCounter = 0;
		}

		// 描画タイミングのカウンタを加算
		plotCounter++;
	}

	//メインループを抜けたらプログラム終了
	exit();
}


/**
 * 初期化処理を行います。
 */
void initialize(){

	// 頂点Xの初期値設定
	for(int i=0; i<N; i++){
		float x = i * LENGTH / N;
		vertexX[i] = x;
	}

	// 頂点Yの初期値設定
	float centerX = LENGTH / 2;
	for(int i=0; i<N; i++){

		// 初期位置、初期速度共に 0（静止状態）
		vertexY[i] = 0.0;
		vertexVY[i] = 0.0;
	}

	// グラフを起動
	graph = newGraph2D(
		SLIDER_WINDOW_WIDTH, 0,
		GRAPH_WINDOW_WIDTH, GRAPH_WINDOW_HEIGHT,
		"Wave Graph"
	);

	// 範囲の自動調整機能をOFFに
	setGraph2DAutoRange(graph, false, false);

	// 範囲を設定
	setGraph2DRange(graph, 0.0, LENGTH, SLIDER_AMPLITUDE, -SLIDER_AMPLITUDE);

	// 初期値をプロット
	setGraph2DData(graph, vertexX, vertexY);

	// 画面の構築
	createUI();
}


/**
 * 1ステップの時間発展を行います。
 */
void update(){

	// 左端の質点をスライダーの値に同期させる
	vertexY[0] = sliderValue;

	// 質点間の距離
	float dx = LENGTH / N;

	// 質点1個あたりの質量
	float m = DENSITY * LENGTH / (N+1);

	// 端以外の頂点にかかる力の計算
	for(int i=1; i<N-1; i++){

		vertexFY[i] =
			(vertexY[i+1]+vertexY[i-1]-2.0*vertexY[i])
			* TENSION/dx - FRICTION*vertexVY[i];
	}

	// 左端はスライダーに固定されているので固定端
	vertexFY[0] = 0.0;

	// 右端にかかる力の計算
	if(freeEnd){ // 自由端

		// 隣接する1個の質点からのみ力を受ける
		vertexFY[N-1] =
			(vertexY[N-2]-vertexY[N-1])
			* TENSION/dx - FRICTION*vertexVY[N-1];

	}else{ //固定端

		// 壁から固定する抗力を受けるので、合力は0で動かない
		vertexFY[N-1] = 0.0;

		// 実行中に自由端/固定端を切り替え可能なので、位置と速度も一応 0 に
		vertexVY[N-1] = 0.0;
		vertexY[N-1] = 0.0;
	}

	// 位置と速度の計算
	for(int i=0; i<N; i++){

		// 頂点の速度変化の計算
		vertexVY[i] += vertexFY[i] / m * DT;

		// 頂点の座標変化の計算
		vertexY[i] += vertexVY[i] * DT;
	}
}


// 画面のレイアウトなど
const int SLIDER_WINDOW_WIDTH = 150;
const int SLIDER_WINDOW_HEIGHT = 600;
const int GRAPH_WINDOW_WIDTH = 700;
const int GRAPH_WINDOW_HEIGHT = 600;
const int FREE_END_BOX_X = 10;
const int FREE_END_BOX_Y = 10;
const int FREE_END_BOX_WIDTH = 150;
const int FREE_END_BOX_HEIGHT = 30;
const int SLIDER_X = 0;
const int SLIDER_Y = 100;
const int SLIDER_WIDTH = SLIDER_WINDOW_WIDTH - 20;
const int SLIDER_HEIGHT = SLIDER_WINDOW_HEIGHT - SLIDER_Y - FREE_END_BOX_HEIGHT - FREE_END_BOX_Y - 30;

// GUIコンポーネントのIDを保持する変数
int sliderWindow;
int slider;
int freeEndBox;

/**
 * 画面の構築を行います。
 */
void createUI(){

	// スライダーウィンドウを生成
	string windowTitle = "Slider";
	sliderWindow = newWindow(
		0, 0,
		SLIDER_WINDOW_WIDTH, SLIDER_WINDOW_HEIGHT,
		windowTitle
	);

	// 自由端の選択ボックスを生成
	string boxTitle = "自由端 (右)";
	bool boxInitState = false;
	freeEndBox = newCheckBox(
		FREE_END_BOX_X, FREE_END_BOX_Y,
		FREE_END_BOX_WIDTH, FREE_END_BOX_HEIGHT,
		boxTitle, boxInitState
	);

	// 自由端の選択ボックスをスライダーウィンドウに配置
	mountComponent(freeEndBox, sliderWindow);

	// 垂直スライダーを生成
	float initValue = 0.0;
	float maxValue = SLIDER_AMPLITUDE;
	float minValue = -SLIDER_AMPLITUDE;
	slider = newVerticalSlider(
		SLIDER_X, SLIDER_Y,
		SLIDER_WIDTH, SLIDER_HEIGHT,
		initValue, minValue, maxValue
	);

	// 垂直スライダーをスライダーウィンドウに配置
	mountComponent(slider, sliderWindow);
}



/**
 * 選択ボックスが操作された時にコールされます。
 * (イベントハンドラ)
 */
void onCheckBoxClick(int componentID, bool value){
	if(componentID == freeEndBox){
		freeEnd = value;
	}
}



/**
 * ウィンドウが閉じられた時にコールされます。
 * (イベントハンドラ)
 */
void onWindowClose(int componentID){
	if(componentID == sliderWindow){
		// メインループを脱出してプログラムを終了させる
		mainLoopState = false;
	}
}



/**
 * スライダーが操作された時にコールされます。
 * (イベントハンドラ)
 */
void onSliderMove(int componentID, float value){
	if(componentID == slider){
		sliderValue = value;
	}
}

coding UTF-8;

import GUI;
import Math;
import tool.Graph2D;

/**
 * 初期化処理を行います。
 */
void initialize(){

	// 頂点Xの初期値設定
	for(int i=0; i<N; i++){
		float x = i * LENGTH / N;
		vertexX[i] = x;
	}

	// 頂点Yの初期値設定
	float centerX = LENGTH / 2;
	for(int i=0; i<N; i++){

		// 初期位置、初期速度共に 0（静止状態）
		vertexY[i] = 0.0;
		vertexVY[i] = 0.0;
	}

	// グラフを起動
	graph = newGraph2D(
		SLIDER_WINDOW_WIDTH, 0,
		GRAPH_WINDOW_WIDTH, GRAPH_WINDOW_HEIGHT,
		"Wave Graph"
	);

	// 範囲の自動調整機能をOFFに
	setGraph2DAutoRange(graph, false, false);

	// 範囲を設定
	setGraph2DRange(graph, 0.0, LENGTH, SLIDER_AMPLITUDE, -SLIDER_AMPLITUDE);

	// 初期値をプロット
	setGraph2DData(graph, vertexX, vertexY);

	// 画面の構築
	createUI();
}

// 画面のレイアウトなど
const int SLIDER_WINDOW_WIDTH = 150;
const int SLIDER_WINDOW_HEIGHT = 600;
const int GRAPH_WINDOW_WIDTH = 700;
const int GRAPH_WINDOW_HEIGHT = 600;
const int FREE_END_BOX_X = 10;
const int FREE_END_BOX_Y = 10;
const int FREE_END_BOX_WIDTH = 150;
const int FREE_END_BOX_HEIGHT = 30;
const int SLIDER_X = 0;
const int SLIDER_Y = 100;
const int SLIDER_WIDTH = SLIDER_WINDOW_WIDTH - 20;
const int SLIDER_HEIGHT = SLIDER_WINDOW_HEIGHT - SLIDER_Y - FREE_END_BOX_HEIGHT - FREE_END_BOX_Y - 30;

// GUIコンポーネントのIDを保持する変数
int sliderWindow;
int slider;
int freeEndBox;

/**
 * 画面の構築を行います。
 */
void createUI(){

	// スライダーウィンドウを生成
	sliderWindow = newWindow(0, 0, SLIDER_WINDOW_WIDTH, SLIDER_WINDOW_HEIGHT, "");

	// 自由端の選択ボックスを生成
	string boxTitle = "自由端 (右)";
	bool boxInitState = false;
	freeEndBox = newCheckBox(
		FREE_END_BOX_X, FREE_END_BOX_Y,
		FREE_END_BOX_WIDTH, FREE_END_BOX_HEIGHT,
		boxTitle, boxInitState
	);

	// 自由端の選択ボックスをスライダーウィンドウに配置
	mountComponent(freeEndBox, sliderWindow);

	// 垂直スライダーを生成
	float initValue = 0.0;
	float maxValue = SLIDER_AMPLITUDE;
	float minValue = -SLIDER_AMPLITUDE;
	slider = newVerticalSlider(
		SLIDER_X, SLIDER_Y,
		SLIDER_WIDTH, SLIDER_HEIGHT,
		initValue, minValue, maxValue
	);

	// 垂直スライダーをスライダーウィンドウに配置
	mountComponent(slider, sliderWindow);
}

/**
 * 1ステップの時間発展を行います。
 */
void update(){

	// 左端の質点をスライダーの値に同期させる
	vertexY[0] = sliderValue;

	// 質点間の距離
	float dx = LENGTH / N;

	// 質点1個あたりの質量
	float m = DENSITY * LENGTH / (N+1);

	// 端以外の頂点にかかる力の計算
	for(int i=1; i<N-1; i++){

		vertexFY[i] =
			(vertexY[i+1]+vertexY[i-1]-2.0*vertexY[i])
			* TENSION/dx - FRICTION*vertexVY[i];
	}

	// 左端はスライダーに固定されているので固定端
	vertexFY[0] = 0.0;

	// 右端にかかる力の計算
	if(freeEnd){ // 自由端

		// 隣接する1個の質点からのみ力を受ける
		vertexFY[N-1] =
			(vertexY[N-2]-vertexY[N-1])
			* TENSION/dx - FRICTION*vertexVY[N-1];

	}else{ //固定端

		// 壁から固定する抗力を受けるので、合力は0で動かない
		vertexFY[N-1] = 0.0;

		// 実行中に自由端/固定端を切り替え可能なので、位置と速度も一応 0 に
		vertexVY[N-1] = 0.0;
		vertexY[N-1] = 0.0;
	}

	// 位置と速度の計算
	for(int i=0; i<N; i++){

		// 頂点の速度変化の計算
		vertexVY[i] += vertexFY[i] / m * DT;

		// 頂点の座標変化の計算
		vertexY[i] += vertexVY[i] * DT;
	}
}

/**
 * 選択ボックスが操作された時にコールされます。
 * (イベントハンドラ)
 */
void onCheckBoxClick(int componentID, bool value){
	if(componentID == freeEndBox){
		freeEnd = value;
	}
}



/**
 * ウィンドウが閉じられた時にコールされます。
 * (イベントハンドラ)
 */
void onWindowClose(int componentID){
	if(componentID == sliderWindow){
		// メインループを脱出してプログラムを終了させる
		mainLoopState = false;
	}
}



/**
 * スライダーが操作された時にコールされます。
 * (イベントハンドラ)
 */
void onSliderMove(int componentID, float value){
	if(componentID == slider){
		sliderValue = value;
	}
}