標準ファイル入出力

ここでは、単純なファイル入出力（読み書き）を行う方法を扱います。

スポンサーリンク

標準ファイル出力

例として、「world.txt」というファイルに文字列を書き込んでみましょう：

// ファイルをテキスト書き込みモードで開く
int fileID = open("world.txt", "w");

// ファイルに書き込む
write(fileID, "Hello world !");

// ファイルを閉じる
close(fileID);

これを実行すると、プログラムと同じ場所に「world.txt」というファイルが生成され、中に「 Hello world ! 」と記述されているはずです。

上の open 関数では、最初の引数にファイル名 "world.txt" を、次の引数にテキスト書き込みモード "w" を指定しています（定数 WRITE による指定もできます）。 モードには、他にも様々なものがあります。

open 関数は、開いたファイルに固有の識別番号「ファイルID」を割り当てて返します。 上ではそれをint 型変数 file で受け取っています。

ファイルへの書き込み/読み込み処理や、ファイルを閉じる場合には、上の例のように、 対象ファイルのファイルIDを指定します。 このように、ファイルIDで対象を識別する仕組みにより、 複数のファイルを同時に操作する事ができます。

1行ごとの書き込み

ファイル内に、行単位で内容を書いていきたい場面もよくあります。その際、C言語ユーザーの方などは、

write(fileID, "Hello world ! \n");

のように、書き込み内容の末尾に「\n」を付けるというコードを書かれるかもしません。これも一応は動くのですが、改行コードの環境依存性によるややこしさが生じるため、VCSSLではあまり推奨されません。代わりに、環境に応じた改行コードで改行をしてくれる、 writeln 関数の使用が推奨されます：

// ファイルをテキスト書き込みモードで開く
int fileID = open("world.txt", "w");

// ファイルに1行ずつ、3行書き込む
writeln(fileID, "Hello");
writeln(fileID, "World");
writeln(fileID, "!");

// ファイルを閉じる
close(fileID);

// ファイルを閉じる
close(fileID);

標準ファイル入力

今度は、先のファイルを読み込んでみましょう：

// ファイルをテキスト読み込みモードで開く
int fileID = open("world.txt", "r");

// ファイルから読み込む
string text = read(fileID);

// ファイルを閉じる
close(fileID);

// 読み込み内容を表示
print(text);

上のopen 関数の引数 "r" はテキスト読み込みモードを意味します。 read 関数は、読み込んだファイルの内容を返します（定数 READ による指定もできます）。

read 関数の戻り値は、一般にはstring 型配列ですが、テキストモード（ "r" ） モードでは要素数1 の配列を返すので、 非配列の変数 text で受け取れます。VCSSLでは、要素数 1 の配列は、非配列の変数にそのまま代入できるからです。

ただしバイナリモード（ "rb" ）ではバイト区切り、 TSV モード（ "rtsv" ）では空白・タブ区切り、CSV モード（ "rcsv" ） ではカンマ区切りの配列で返されるため、配列変数で受け取る必要があります。

1行ごとの読み込み

ファイルを1 行ごとに読み込むには、以下のようにします：

// ファイルをテキスト読み込みモードで開く
int fileID = open("world.txt", "r");

// ファイル行数を取得
int n = countln(fileID);

for( int i=0; i<n; i++ ){

    // ファイルから一行読み込む
    string line = readln(fileID);

    // 読み込み内容を表示
    println(i + "行目=" + line);
}

// ファイルを閉じる
close(fileID);

このように、まず countln 関数でファイル行数をカウントし、 そして readln 関数で1 行ずつ読み込みます。先のread 関数はファイル全体を一度に読み込むためのものでしたが、 readln 関数は1 行単位で読み込むためのもので、それ以外は同じです。

標準ファイル入出力関数の仕様

上の例で用いた open 関数や readln 関数などは、標準ファイル入出力関数というもので、System ライブラリによって提供されます。

標準ファイル入出力関数の一覧

ファイル入出力モードの一覧

ファイル入出力関数の、open 関数の第二引数に指定するモードには、以下のものが存在します。

書き込みモード

読み込みモード

各モードの詳細と留意点

テキスト書き込み/読み込みモード

これらのモードは、普通のテキストファイルを扱うためのモードです。書き込み時には、引数に指定された文字列や値を、そのままテキストとしてファイル内に書き込みます。複数の引数を指定しても、区切り文字などは付かず、連続して書き込まれます。読み込み時にも、1行の内容すべてが、要素数 1 の string 配列として返されます。

バイナリ書き込み/読み込みモード

これらのモードは、バイト値を直接読み書きするためのモードです。VCSSLには1バイトぴったりの値を扱う型は無いため、読み書きは int 型の値で行います。例えば int 値の列 1, 2, 4 を書き込むと、それがそのまま符号なしバイト値 1, 2, 4 (2進数表現で 00000001, 00000010, 00000100) の列として書き込まれます。なお、1バイトに書き込み可能な値の上限は 255 (11111111) である事にご注意ください。

TSV書き込み/読み込みモード

これらのモードは、タブ・空白区切りの数値データファイルを扱うためのモードで、 CSV書き込み/読み込みモードはカンマ区切り数値データファイルのモードです。基本的に数値データを扱う事を想定したもので、単純な挙動を行います。そのため、書き込む値の中に区切り文字自身や改行が含まれていても、引用符で囲ったり、エスケープしたりなどの処理は一切されません。読み込みの際にも、そういった事を想定した処理は行われません。そのような複雑な処理を要するCSV/TSVファイルを扱う機能は、代わりに open.file.TextFile ライブラリが提供します。

y=x^2の値をCSV数値データファイルに書き出す

例として、CSV 数値データファイルを扱います。まずは書き込みです。 y=x^2 の計算結果を、ファイルに出力してみましょう：

// ファイルをCSV 書き込みモードで開く
int fileID = open("x2.csv", "wcsv");

for (int i=0; i<=10; i++) {

    // ファイルに一行書き込み、改行
    writeln(fileID, i, i*i);
}

close(fileID);

これを実行すると、プログラムと同じ場所に、以下のような内容が書かれたファイル「x2.csv」が生成されます：

このような形式のファイルは、一般的なグラフソフトを用いてグラフ化する事ができます。VCSSLのグラフ描画機能でも使用できます。

y=x^2のCSV数値データファイルを読み込む

上で作ったy=x^2 の数値データファイルを、今度は読み込んでみましょう：

// ファイルをCSV 読み込みモードで開く
int fileID = open("x2.csv", "rcsv");

// ファイル行数を取得
int n = countln(fileID);


// 各行の値（カンマ区切り）を受け取る変数
int x[n];
int y[n];

for (int i=0; i<n; i++) {

    // 次の行を読み込み
    int[] line = readln(fileID);

    // 行内の最初と次の値を x, y に代入
    x[i] = line[0];
    y[i] = line[1];
}

close(fileID);

// 読み込んだ内容を表示
for(int i=0; i<n; i++) {
    println(x[i], y[i]);
}

このプログラムを実行すると、先ほど作ったy=x^2 のデータファイルを読み込んで配列に格納し、 その内容をコマンドライン端末などに表示します。

上の readln 関数が最初に呼ばれると、ファイルの先頭行をカンマ記号「 , 」で区切って、 string 配列に格納して返ってきます。それを int 型配列のline で受け取っています。この際、暗黙の型変換により、文字列が整数へキャストされます。

line[0] は、行の中での最初の値（x値）なので、int 型配列 x に値を格納しています。同様に、行の中での次の値 line[1] は配列 y に格納しています。 これで1 行の読み込みが終わります。

readln 関数はfor 関数の中にあるので、10 回繰り返して呼ばれます。2 回目に呼ばれた際はファイルの 2 行目が呼ばれます。 このように、10 行目まで読み込み、プログラムが終了されます。

文字コードの指定

異なるオペレーションシステム上で作成したファイルをやり取りする場合などでは、 文字コードの違いによって、いわゆる文字化けが問題となる場合があります。 このような場合のために、open 関数には、引数の最後に string 型の引数を追加して文字コードを指定する事ができます。

int file = open("utf8.txt", "w", "UTF-8");
write(file, "こんにちは ! ");
close(file);

使用できる文字コードには以下のものがあります：

上の文字コードは、正式な表記で記述しなければ無効となります。 例えばShift_JIS をShift-JIS と書くと向こうなのでご注意下さい。 同様にUTF-8 をUTF_8 と書いても無効となります。 大文字と小文字も区別されるため、完全に上記の通りに記述する必要があります。