coding Shift_JIS;	// 文字コードの明示（文字化け予防）
import Graphics;	// 画像処理に必要なライブラリの読み込み
import File;        // ファイルやフォルダの情報を扱うライブラリの読み込み
import Text;        // 文字列の操作や判定などに必要なライブラリの読み込み


// 入出力フォルダのパスのデフォルト値
const string DEFAULT_INPUT_DIRECTORY = "./input";
const string DEFAULT_OUTPUT_DIRECTORY = "./output";

// 切り抜く領域の座標をユーザーに指定してもらう
int leftTopX = input("切り抜く領域の左上端のX座標は？", "100");
int leftTopY = input("切り抜く領域の左上端のY座標は？", "50");
int width = input("切り抜く領域の幅は？", "300");
int height = input("切り抜く領域の高さは？", "200");

// 保存画像形式などをユーザーに指定してもらう
string saveFormat = select("- 保存する画像形式を選択 -", "PNG", "JPEG");
while (saveFormat == "- 保存する画像形式を選択 -") {
	saveFormat = select("- 保存する画像形式を選択 -", "PNG", "JPEG");
}
float quality = 100.0;
if (saveFormat == "JPEG") {
	quality = input("画質（%）を選択（0.0 〜 100.0）", "100.0");
}


// ==================================================
// 全体的な処理 - この関数は起動時に自動で実行されます
// ==================================================

void main () {
	
	// 入出力フォルダのフルパスを用意
	string inputDirectoryPath = getFilePath(DEFAULT_INPUT_DIRECTORY);
	string outputDirectoryPath = getFilePath(DEFAULT_OUTPUT_DIRECTORY);
	
	// 入出力フォルダをデフォルトから変更するかユーザーに尋ね、必要なら変更
	if (confirm("入力先/出力先フォルダを指定しますか？（「いいえ」でデフォルトの場所使用）")) {
		inputDirectoryPath = choose("入力先フォルダを選択", ".");
		outputDirectoryPath = choose("出力先フォルダを選択", ".");
	}
	
	// 入力先フォルダ内の全ファイルを処理し、出力先フォルダに保存
	processAllFiles(inputDirectoryPath, outputDirectoryPath);
	
	// 完了メッセージをユーザーに表示
	popup("完了しました。画面上のファイル一覧を確認の上、ウィンドウを閉じてください。");
}


// ==================================================
// フォルダ内の全ファイルを走査して処理する関数
// ==================================================

void processAllFiles(string inputDirectoryPath, string outputDirectoryPath) {
	
	// 入力フォルダ内にあるファイル名の一覧とファイル個数を取得
	string fileNames[] = listDirectory(inputDirectoryPath);
	int fileN = length(fileNames);
	
	// 入力フォルダ内にある個々のファイルについて処理
	for (int i=0; i<fileN; i++) {
		
		// ファイル名の入力フォルダのパスを結合して、ファイルパスに変換
		string inputFilePath = getFilePath(fileNames[i], inputDirectoryPath);
		
		// フォルダではなく、PNG/JPEG形式の拡張子が付いてれば、入力ファイルと見なす
		if (!isDirectory(inputFilePath) && checkText(inputFilePath, ".(png|jpg)", Text.END_PATTERN)) {
			
			// 入力ファイル名から出力ファイル名（入力ファイル名+_crop.png/jpg）を求める
			string outputFileName = fileNames[i] + "_crop";
			if (saveFormat == "PNG") {
				outputFileName += ".png";
			} else (saveFormat == "JPEG") {
				outputFileName += ".jpg";
			}
			
			// 出力ファイル名に出力フォルダのパスを合成して、ファイルパスに変換
			string outputFilePath = getFilePath(outputFileName, outputDirectoryPath);
			
			// これから処理する入出力ファイルのパスをコンソールに表示
			println("INPUT: " + inputFilePath);
			println("  > OUTPUT: " + outputFilePath);
			
			// 画像の切り抜き・保存処理を実行
			processFile(inputFilePath, outputFilePath);
		}
	}
}


// ==================================================
// 画像ファイル1個を読み込み、透過処理して保存する関数
// ==================================================

void processFile(string inputFilePath, string outputFilePath) {
	
	// 画像ファイルを開き、その内容を保持するグラフィックスデータを生成
	int inputGraphics = newGraphics(inputFilePath);
	
	// inputGraphicsの矩形（四角形）領域内の内容を保持する、新しいグラフィックスデータを生成
	int outputGraphics = newGraphics(inputGraphics, leftTopX, leftTopY, width, height);
	
	// 別のファイル名をつけて保存
	exportGraphics(outputGraphics, outputFilePath, saveFormat, quality);
	
	// リソースを破棄
	deleteGraphics(inputGraphics);
	deleteGraphics(outputGraphics);
}