coding Shift_JIS;

import Math;
import Text;
import GUI;
import File;
import tool.Graph2D;


/** 積分値を表示する際、丸める桁数（有効桁数）です。*/
const int RESULT_ROUNDING_DIGITS = 10;

/** コンソール上のX値を丸める桁数（有効桁数）です。 */
const int X_ROUNDING_DIGITS = 10;

/** 積分する数式 f(x) のデフォルト入力値です。 */
const string DEFAULT_EXPRESSION = "exp( 3 * sin(26 * x) )";

/** 積分区間の上端のデフォルト入力値です。 */
const string DEFAULT_X_MAX = "1.0";

/** 積分区間の下端のデフォルト入力値です。 */
const string DEFAULT_X_MIN = "0.0";

/** 数値積分での区間分割数のデフォルト入力値です。 */
const string DEFAULT_X_N = "10000";

/** シンプソン法のアルゴリズム名です。 */
const string ALGORITHM_NAME_SIMPSON = "SIMPSON - シンプソン法";

/** 台形法（台形近似）のアルゴリズム名です。 */
const string ALGORITHM_NAME_TRAPEZOIDAL = "TRAPEZOIDAL - 台形法";

/** 矩形法（長方形近似）のアルゴリズム名です。 */
const string ALGORITHM_NAME_RECTANGULAR = "RECTANGULAR - 矩形法(長方形近似)";

/** アルゴリズム名を格納する配列です。 */
const string ALGORITHM_NAMES[] = { ALGORITHM_NAME_SIMPSON, ALGORITHM_NAME_TRAPEZOIDAL, ALGORITHM_NAME_RECTANGULAR };


// 以下、グラフやGUIコンポーネントIDを格納する変数

/** グラフのIDを格納します。 **/
int graph = NULL;

/** 入力画面のウィンドウのIDを格納します。 */
int window = NULL;

/** 積分する数式を入力するテキストフィールドのIDを格納します。 */
int expressionField = NULL;

/** 積分された値を出力するテキストフィールドのIDを格納します。 */
int resultField = NULL;

/** X軸の最大値を入力するテキストフィールドのIDを格納します。 */
int xMaxField = NULL;

/** X軸の最小値を入力するテキストフィールドのIDを格納します。 */
int xMinField = NULL;

/** 数値積分での区間分割数を入力するテキストフィールドのIDを格納します。 */
int xNField = NULL;

/** アルゴリズム選択項目のIDを格納します。 */
int algorithmSelectField = NULL;

/** グラフをプロットするかどうかを選択するチェックボックスのIDを格納します。 */
int plotCheckBox = NULL;

/** CALCボタンのIDを格納します。 */
int calcButton = NULL;



/**
 * プログラムの開始時に自動で実行されます。
 */
void main(){

	// 入力画面を起動
	createInputWindow();

	// ※ ユーザーがボタンを押すとグラフが描かれる処理などは、
	// 後で定義している onButtonClick 関数を起点として実行されます。
}


/**
 * 文字列として渡された式を矩形法（長方形近似）で数値積分し、結果を返します。
 * 
 * @param fxEexpr 被積分関数の式（文字列）
 * @param xMin 積分区間の下端
 * @param xMax 積分区間の上端
 * @param n 数値積分の区間分割数
 * @param plotGraph 積分過程をグラフに描画するかどうか(trueなら描画する)
 * @return 積分結果の値
 */
float integrateRectangular(string fxExpr, float xMin, float xMax, int n, bool plotGraph) {
	
	// コンソールの内容をクリア
	clear();
	
	// 数値積分の微小区間の幅
	float dx = (xMax-xMin) / n;
	
	// 積分値
	float value = 0.0;
	
	// f(x) を微小区間ごとに二次関数近似し、面積を足していくループ（シンプソン法）
	for (int i=0; i<n; i++) {
		
		// 微小区間の左端のX値
		float xLeft = xMin + i * dx;
		
		// 積分過程をグラフに描く場合は、毎ループの先頭で x と積分値をコンソールに出力
		if (plotGraph) {
			println( round(xLeft, X_ROUNDING_DIGITS, System.HALF_UP_SIGNIF), value);
		}
		
		// 被積分関数 f(x) の式の中で参照する x 値の変数
		float x;
		
		// 微小区間左端での被積分関数 f(xLeft) の値を求める
		x = xLeft;
		float fxLeft = feval(fxExpr, 0.0); // fevalは文字列を式として評価しfloat値にして返す関数
		
		// 微小区間の長方形（矩形）の面積を、現在の積分値に足す
		value += fxLeft * dx;
	}
	
	// 右端の点は必ずグラフに含めたい上に、グラフを描かない場合も丸めていない値を確認できるように、
	// 最後に一回コンソールに値を書き出す
	println(xMax, value);
	
	// グラフの起動と描画
	if (plotGraph) {
		
		// 2Dグラフを起動してオプションを設定
		int graph = launchGraph(fxExpr); // launchGraph 関数はこのコード内の後方で定義
		
		// コンソールに出力した内容を文字列として取得し、それをグラフに渡してプロットする
		string data = load();
		setGraph2DData(graph, data);
	}
	return value;
}


/**
 * 文字列として渡された式を台形法（台形近似）で数値積分し、結果を返します。
 * 
 * @param fxEexpr 被積分関数の式（文字列）
 * @param xMin 積分区間の下端
 * @param xMax 積分区間の上端
 * @param n 数値積分の区間分割数
 * @param plotGraph 積分過程をグラフに描画するかどうか(trueなら描画する)
 * @return 積分結果の値
 */
float integrateTrapezoidal(string fxExpr, float xMin, float xMax, int n, bool plotGraph) {
	
	// コンソールの内容をクリア
	clear();
	
	// 数値積分の微小区間の幅
	float dx = (xMax-xMin) / n;
	
	// 積分値
	float value = 0.0;
	
	// f(x) を微小区間ごとに二次関数近似し、面積を足していくループ（シンプソン法）
	for (int i=0; i<n; i++) {
		
		// 微小区間の左端のX値
		float xLeft = xMin + i * dx;
		
		// 積分過程をグラフに描く場合は、毎ループの先頭で x と積分値をコンソールに出力
		if (plotGraph) {
			println( round(xLeft, X_ROUNDING_DIGITS, System.HALF_UP_SIGNIF), value);
		}
		
		// 被積分関数 f(x) の式の中で参照する x 値の変数
		float x;
		
		// 微小区間左端での被積分関数 f(xLeft) の値を求める
		x = xLeft;
		float fxLeft = feval(fxExpr, 0.0); // fevalは文字列を式として評価しfloat値にして返す関数
		
		// 微小区間右端での被積分関数 f(xLeft + dx) の値を求める
		x = xLeft + dx;
		float fxRight = feval(fxExpr, 0.0);
		
		// 微小区間の台形の面積を、現在の積分値に足す
		value += (fxLeft + fxRight) * dx / 2.0;
	}
	
	// 右端の点は必ずグラフに含めたい上に、グラフを描かない場合も丸めていない値を確認できるように、
	// 最後に一回コンソールに値を書き出す
	println(xMax, value);
	
	// グラフの起動と描画
	if (plotGraph) {
		
		// 2Dグラフを起動してオプションを設定
		int graph = launchGraph(fxExpr); // launchGraph 関数はこのコード内の後方で定義
		
		// コンソールに出力した内容を文字列として取得し、それをグラフに渡してプロットする
		string data = load();
		setGraph2DData(graph, data);
	}
	return value;
}


/**
 * 文字列として渡された式をシンプソン法で数値積分し、結果を返します。
 * 
 * @param fxEexpr 被積分関数の式（文字列）
 * @param xMin 積分区間の下端
 * @param xMax 積分区間の上端
 * @param n 数値積分の区間分割数
 * @param plotGraph 積分過程をグラフに描画するかどうか(trueなら描画する)
 * @return 積分結果の値
 */
float integrateSimpson(string fxExpr, float xMin, float xMax, int n, bool plotGraph) {
	
	// コンソールの内容をクリア
	clear();
	
	// 数値積分の微小区間の幅
	float dx = (xMax-xMin) / n;
	
	// 積分値
	float value = 0.0;
	
	// f(x) を微小区間ごとに二次関数近似し、面積を足していくループ（シンプソン法）
	for (int i=0; i<n; i++) {
		
		// 微小区間の左端のX値
		float xLeft = xMin + i * dx;
		
		// 積分過程をグラフに描く場合は、毎ループの先頭で x と積分値をコンソールに出力
		if (plotGraph) {
			println( round(xLeft, X_ROUNDING_DIGITS, System.HALF_UP_SIGNIF), value);
		}
		
		// 被積分関数 f(x) の式の中で参照する x 値の変数
		float x;
		
		// 微小区間左端での被積分関数 f(xLeft) の値を求める
		x = xLeft;
		float fxLeft = feval(fxExpr, 0.0); // fevalは文字列を式として評価しfloat値にして返す関数
		
		// 微小区間右端での被積分関数 f(xLeft + dx) の値を求める
		x = xLeft + dx;
		float fxRight = feval(fxExpr, 0.0);
		
		// 微小区間中央での被積分関数 f(xLeft + dx/2) の値を求める
		x = xLeft + dx / 2.0;
		float fxCenter = feval(fxExpr, 0.0);
		
		// 上記3地点でのf(x)の値に重みをつけて微小区間面積を求め、足す
		value += ( fxLeft + fxRight + 4.0 * fxCenter ) * dx / 6.0;
	}
	
	// 右端の点は必ずグラフに含めたい上に、グラフを描かない場合も丸めていない値を確認できるように、
	// 最後に一回コンソールに値を書き出す
	println(xMax, value);
	
	// グラフの起動と描画
	if (plotGraph) {
		
		// 2Dグラフを起動してオプションを設定
		int graph = launchGraph(fxExpr); // launchGraph 関数はこのコード内の後方で定義
		
		// コンソールに出力した内容を文字列として取得し、それをグラフに渡してプロットする
		string data = load();
		setGraph2DData(graph, data);
	}
	return value;
}


/**
 * 2Dグラフを起動し、オプションやラベルなどを設定して、グラフのIDを返します。
 * 
 * @param fxExpr 被積分関数 f(x) の式（ラベルやタイトルの内容に使用）
 * @return 起動したグラフのID
 */
int launchGraph(string fxExpr) {
	string graphTitle = "∫ " + fxExpr + " dx";
	int graph = newGraph2D(480, 30, 820, 700, graphTitle);
	setGraph2DOption(graph, "WITH_LINES", true);
	setGraph2DOption(graph, "WITH_POINTS", false);
	setGraph2DLabel(graph, "b", graphTitle + "   from  a  to  b");
	return graph;
}


/**
 * 数式などを入力する、入力画面のGUIを構築して起動します。
 */
void createInputWindow(){

	int leftWidth = 140;
	int rightX = leftWidth + 10;
	int rightWidth = 260;
	int fullWidth = 400;
	int fontSize = 20;
	
	window = newWindow( 20, 30, 450, 450, "Input Window" );

	int expressionLabel = newTextLabel( 10, 10, leftWidth, 25, "f(x) =" );
	setComponentFontSize(expressionLabel, fontSize);
	mountComponent( expressionLabel, window );

	expressionField = newTextField( rightX, 10, rightWidth, 25, DEFAULT_EXPRESSION );
	setComponentFontSize(expressionField, fontSize);
	mountComponent( expressionField, window );

	int xMaxLabel = newTextLabel( 10, 60, leftWidth, 25, "b (x_max) =" );
	setComponentFontSize(xMaxLabel, fontSize);
	mountComponent( xMaxLabel, window );

	xMaxField = newTextField( rightX, 60, rightWidth, 25, DEFAULT_X_MAX );
	setComponentFontSize(xMaxField, fontSize);
	mountComponent( xMaxField, window );

	int xMinLabel = newTextLabel( 10, 90, leftWidth, 25, "a (x_min) =" );
	setComponentFontSize(xMinLabel, fontSize);
	mountComponent( xMinLabel, window );

	xMinField = newTextField( rightX, 90, rightWidth, 25, DEFAULT_X_MIN );
	setComponentFontSize(xMinField, fontSize);
	mountComponent( xMinField, window );


	int xNLabel = newTextLabel( 10, 120, leftWidth, 25, "N =" );
	setComponentFontSize(xNLabel, fontSize);
	mountComponent( xNLabel, window );

	xNField = newTextField( rightX, 120, rightWidth, 25, DEFAULT_X_N );
	setComponentFontSize(xNField, fontSize);
	mountComponent( xNField, window );


	int algorithmLabel = newTextLabel( 10, 150, leftWidth, 25, "Algorithm =" );
	setComponentFontSize(algorithmLabel, fontSize);
	mountComponent( algorithmLabel, window );

	algorithmSelectField = newSelectField( rightX, 150, rightWidth, 25, ALGORITHM_NAMES );
	mountComponent( algorithmSelectField, window );


	plotCheckBox = newCheckBox( 10, 250, fullWidth, 25, "Plot Graph - グラフを描画", true);
	setComponentFontSize(plotCheckBox, fontSize);
	mountComponent( plotCheckBox, window );


	calcButton = newButton( 10, 280, fullWidth, 50, "CALC - 計算" );
	setComponentFontSize(calcButton, fontSize);
	mountComponent( calcButton, window );

	int resultLabel = newTextLabel( 10, 350, leftWidth, 25, "[∫f(x)dx] =" );
	setComponentFontSize(resultLabel, fontSize);
	mountComponent( resultLabel, window );

	resultField = newTextField( rightX, 350, rightWidth, 25, "" );
	setComponentFontSize(resultField, fontSize);
	mountComponent( resultField, window );
}


/**
 * 入力画面上の入力項目において、式として評価するのに適さない文字を、適切な文字で置き換えます。
 */
void correctCharactersOnInputWindow() {
	
	setComponentText(
		expressionField, 
		correctCharactersInExpression(
			getComponentText(expressionField)
		)
	);
	
	setComponentText(
		xMaxField, 
		correctCharactersInExpression(
			getComponentText(xMaxField)
		)
	);
	
	setComponentText(
		xMinField, 
		correctCharactersInExpression(
			getComponentText(xMinField)
		)
	);
	
	setComponentText(
		xNField, 
		correctCharactersInExpression(
			getComponentText(xNField)
		)
	);
}


/**
 * 文字列内で、式として評価するのに適さない文字を、適切な文字で置き換えます。
 * 
 * @param 式の内容を格納する文字列
 * @return 適切に文字を置き換えた文字列
 */
string correctCharactersInExpression(string expression) {
	string result = expression;
	
	result = replaceText(result, "×", "*", Text.ALL);
	result = replaceText(result, "÷", "/", Text.ALL);
	result = replaceText(result, "＾", "**", Text.ALL);
	result = replaceText(result, "^",  "**", Text.ALL);
	
	result = replaceText(result, "＋", "+", Text.ALL);
	result = replaceText(result, "＊", "*", Text.ALL);
	result = replaceText(result, "／", "/", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "−", "-", Text.ALL);
	result = replaceText(result, "―", "-", Text.ALL);
	result = replaceText(result, "‐", "-", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "％", "%", Text.ALL);
	result = replaceText(result, "（", "(", Text.ALL);
	result = replaceText(result, "）", ")", Text.ALL);
	
	result = replaceText(result, "Ａ", "A", Text.ALL);
	result = replaceText(result, "Ｂ", "B", Text.ALL);
	result = replaceText(result, "Ｃ", "C", Text.ALL);
	result = replaceText(result, "Ｄ", "D", Text.ALL);
	result = replaceText(result, "Ｅ", "E", Text.ALL);
	result = replaceText(result, "Ｆ", "F", Text.ALL);
	result = replaceText(result, "Ｇ", "G", Text.ALL);
	result = replaceText(result, "Ｈ", "H", Text.ALL);
	result = replaceText(result, "Ｉ", "I", Text.ALL);
	result = replaceText(result, "Ｊ", "J", Text.ALL);
	result = replaceText(result, "Ｋ", "K", Text.ALL);
	result = replaceText(result, "Ｌ", "L", Text.ALL);
	result = replaceText(result, "Ｍ", "M", Text.ALL);
	result = replaceText(result, "Ｎ", "N", Text.ALL);
	result = replaceText(result, "Ｏ", "O", Text.ALL);
	result = replaceText(result, "Ｐ", "P", Text.ALL);
	result = replaceText(result, "Ｑ", "Q", Text.ALL);
	result = replaceText(result, "Ｒ", "R", Text.ALL);
	result = replaceText(result, "Ｓ", "S", Text.ALL);
	result = replaceText(result, "Ｔ", "T", Text.ALL);
	result = replaceText(result, "Ｕ", "U", Text.ALL);
	result = replaceText(result, "Ｖ", "V", Text.ALL);
	result = replaceText(result, "Ｗ", "W", Text.ALL);
	result = replaceText(result, "Ｘ", "X", Text.ALL);
	result = replaceText(result, "Ｙ", "Y", Text.ALL);
	result = replaceText(result, "Ｚ", "Z", Text.ALL);
	
	result = replaceText(result, "ａ", "a", Text.ALL);
	result = replaceText(result, "ｂ", "b", Text.ALL);
	result = replaceText(result, "ｃ", "c", Text.ALL);
	result = replaceText(result, "ｄ", "d", Text.ALL);
	result = replaceText(result, "ｅ", "e", Text.ALL);
	result = replaceText(result, "ｆ", "f", Text.ALL);
	result = replaceText(result, "ｇ", "g", Text.ALL);
	result = replaceText(result, "ｈ", "h", Text.ALL);
	result = replaceText(result, "ｉ", "i", Text.ALL);
	result = replaceText(result, "ｊ", "j", Text.ALL);
	result = replaceText(result, "ｋ", "k", Text.ALL);
	result = replaceText(result, "ｌ", "l", Text.ALL);
	result = replaceText(result, "ｍ", "m", Text.ALL);
	result = replaceText(result, "ｎ", "n", Text.ALL);
	result = replaceText(result, "ｏ", "o", Text.ALL);
	result = replaceText(result, "ｐ", "p", Text.ALL);
	result = replaceText(result, "ｑ", "q", Text.ALL);
	result = replaceText(result, "ｒ", "r", Text.ALL);
	result = replaceText(result, "ｓ", "s", Text.ALL);
	result = replaceText(result, "ｔ", "t", Text.ALL);
	result = replaceText(result, "ｕ", "u", Text.ALL);
	result = replaceText(result, "ｖ", "v", Text.ALL);
	result = replaceText(result, "ｗ", "w", Text.ALL);
	result = replaceText(result, "ｘ", "x", Text.ALL);
	result = replaceText(result, "ｙ", "y", Text.ALL);
	result = replaceText(result, "ｚ", "z", Text.ALL);
	
	result = replaceText(result, "１", "1", Text.ALL);
	result = replaceText(result, "２", "2", Text.ALL);
	result = replaceText(result, "３", "3", Text.ALL);
	result = replaceText(result, "４", "4", Text.ALL);
	result = replaceText(result, "５", "5", Text.ALL);
	result = replaceText(result, "６", "6", Text.ALL);
	result = replaceText(result, "７", "7", Text.ALL);
	result = replaceText(result, "８", "8", Text.ALL);
	result = replaceText(result, "９", "9", Text.ALL);
	result = replaceText(result, "０", "0", Text.ALL);
	result = replaceText(result, "．", ".", Text.ALL);
	
	return result;
}


/**
 * ボタンが押された際にコールされます（イベントハンドラ）
 * 
 * @param id 押されたボタンのID
 */
void onButtonClick( int id ){

	// 「CALC」ボタンが押された場合
	if( id == calcButton ){
		
		// 画面上に入力されている文字列内で、式として評価するのに適さない文字を、適切な文字で置き換え
		correctCharactersOnInputWindow();
		
		// 以下、画面から入力内容を取得
		
		string fxExpr = getComponentText( expressionField );
		
		if( !evaluable( getComponentText( xMaxField ), 0.0 ) ){
			alert("x_maxの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( xMinField ), 0.0 ) ){
			alert("x_minの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( xNField ), 0.0 ) ){
			alert("Nの式に誤りがあります。");
			return;
		}
		
		float xMax = feval( getComponentText( xMaxField ), 0.0);
		float xMin = feval( getComponentText( xMinField ), 0.0);
		int n = ieval( getComponentText( xNField ), 0.0);
		bool plotGraph = getComponentBool( plotCheckBox );
		
		float x;
		if( !evaluable(fxExpr, 0.0) ){
			alert("f(x)の式に誤りがあります。");
			return;
		}
		
		// 選択されている数値積分アルゴリズム名を取得
		string algorithmName = getComponentText(algorithmSelectField);
		
		// アルゴリズムに応じて、数値積分を行う関数を実行（ integrate...関数はこのコード内の前半で定義 ）
		float value = 0.0;
		if (algorithmName == ALGORITHM_NAME_SIMPSON) {
			value = integrateSimpson(fxExpr, xMin, xMax, n, plotGraph);
			
		} else if (algorithmName == ALGORITHM_NAME_TRAPEZOIDAL) {
			value = integrateTrapezoidal(fxExpr, xMin, xMax, n, plotGraph);
			
		} else if (algorithmName == ALGORITHM_NAME_RECTANGULAR) {
			value = integrateRectangular(fxExpr, xMin, xMax, n, plotGraph);
		}
		
		// 積分結果を丸める
		if (!nan(value) && !inf(value)) {
			value = round(value, RESULT_ROUNDING_DIGITS, HALF_UP_SIGNIF);
		}
		
		// 積分結果をウィンドウ上のテキストフィールドにセット
		setComponentText( resultField, (string)value );
		
		return;
	}
}


/**
 * ウィンドウが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたウィンドウのID
 */
void onWindowClose( int id ){
	if( id == window ){
		// プログラムの実行を終了する
		exit();
		return;
	}
}


/**
 * グラフが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたグラフのID
 */
void onGraph2DClose( int id ){
	if( id == graph ){
		// 閉じられたグラフのリソースを破棄する
		deleteGraph2D(id);
		return;
	}
}