coding Shift_JIS;

import Math;
import Text;
import GUI;
import File;
import tool.Graph2D;


/** グラフに描画する数式 x(t) のデフォルト入力値です。 */
const string DEFAULT_X_EXPRESSION = "cos(5*t)";

/** グラフに描画する数式 y(t) のデフォルト入力値です。 */
const string DEFAULT_Y_EXPRESSION = "sin(10*t)";

/** 媒介変数 t（時刻）の最大値（終了値）のデフォルト入力値です。 */
const string DEFAULT_T_MAX = "1.0";

/** 媒介変数 t（時刻）の最小値（開始値）のデフォルト入力値です。 */
const string DEFAULT_T_MIN = "-1.0";

/** 媒介変数 t の範囲を分割する点数（プロット点数）のデフォルト入力値です。 */
const string DEFAULT_T_N = "300";


// 以下、グラフやGUIコンポーネントIDを格納する変数

/** グラフのIDを格納します。 **/
int graph = NULL;

/** 入力画面のウィンドウのIDを格納します。 */
int window = NULL;

/** x(t) の数式を入力するテキストフィールドのIDを格納します。 */
int xExpressionField = NULL;

/** y(t) の数式を入力するテキストフィールドのIDを格納します。 */
int yExpressionField = NULL;

/** 時刻 t の最大値を入力するテキストフィールドのIDを格納します。 */
int tMaxField;

/** 時刻 t の最小値を入力するテキストフィールドのIDを格納します。 */
int tMinField;

/** 時刻の刻み数（＝グラフのプロット点数）を入力するテキストフィールドのIDを格納します。 */
int tNField;

/** PLOTボタンのIDを格納します。 */
int plotButton;

/** CLEARボタンのIDを格納します。 */
int clearButton;

/** ANIMATIONボタンのIDを格納します。 */
int animationButton;

/** EXPORTボタンのIDを格納します。 */
int exportButton;

/** EXITボタンのIDを格納します。 */
int exitButton;



/**
 * プログラムの開始時に自動で実行されます。
 */
void main(){

	// GUIを備えたツールではコンソール画面は邪魔なので非表示化
	hide();

	// システム側で標準接続されている2DグラフソフトがあればIDを取得（無ければnewGraph2D関数同様、新規に立ち上がる）
	graph = getGraph2D();

	// ※ 普通に newGraph2D 関数で新規生成しないのは、このプログラムがリニアングラフ2Dにも同梱されるツールであり、
	//	リニアングラフ2D上でメニューからこのプログラムを実行した際に、そのグラフ自身を制御対象とするためです。

	// グラフ画面の位置とサイズを設定
	setGraph2DLocation(graph, 330, 0);
	setGraph2DSize(graph, 720, 600);

	// 設定画面を起動
	createInputWindow();

	// ※ ユーザーがボタンを押すとグラフが描かれる処理などは、
	//	後方の onButtonClick 関数を起点として実行されます。
}


/**
 * 引数に指定された数式をグラフにプロットします。
 * 
 * @param xExpression プロットするxの数式(時刻変数tの関数)
 * @param yExpression プロットするyの数式(時刻変数tの関数)
 * @param yMin 時刻変数tの最小値（開始値）
 * @param yMax 時刻変数tの最大値（終了値）
 * @param n プロット点数
 */
void plotGraph( string xExpression, string yExpression, double tMax, double tMin, int n ){

	// グラフソフトに転送するデータ配列
	double xArray[n];
	double yArray[n];

	// グラフを構成する点の x, y 座標および時刻 t を格納する変数
	//（入力された x, y の数式の中でも変数 t は参照するので、スコープの都合上ここで宣言）
	double x;
	double y;
	double t;

	//  x, y の数式が文法的に正しいか検査
	if( !evaluable(xExpression, 0.0) ){
		alert("x(t)の式に誤りがあります。");
		return;
	}
	if( !evaluable(yExpression, 0.0) ){
		alert("y(t)の式に誤りがあります。");
		return;
	}

	// 時間範囲をn分割した時刻 t において、数式から x, y の値を求め、配列に格納
	float dt = (tMax-tMin)/(n-1);
	for( int i=0; i<n; i++ ){
		t = tMin + i * dt;

		// 文字列の式を解釈してfloatの値を得る（第2引数は式内の整数を浮動小数点数と見なすオプション）
		x = feval( xExpression, 0.0 );
		y = feval( yExpression, 0.0 );

		xArray[ i ] = x;
		yArray[ i ] = y;
	}

	// データ配列をグラフソフトウェアに転送し、追加プロット
	addGraph2DData( graph, xArray, yArray );
}


/**
 * 設定画面を起動します。
 */
void createInputWindow(){

	int fontSize = 20;
	int leftWidth = 120;
	int rightX = leftWidth + 10;
	int rightWidth = 160;
	int buttonWidth = 270;

	window = newWindow( 0, 0, 320, 580, "入力画面" );

	int xExpressionLabel = newTextLabel( 10, 10, leftWidth, 25, "x( t ) =" );
	setComponentFontSize(xExpressionLabel, fontSize);
	mountComponent( xExpressionLabel, window );

	xExpressionField = newTextField( rightX, 10, rightWidth, 25, DEFAULT_X_EXPRESSION );
	setComponentFontSize(xExpressionField, fontSize);
	mountComponent( xExpressionField, window );

	int yExpressionLabel = newTextLabel( 10, 50, leftWidth, 25, "y( t ) =" );
	setComponentFontSize(yExpressionLabel, fontSize);
	mountComponent( yExpressionLabel, window );

	yExpressionField = newTextField( rightX, 50, rightWidth, 25, DEFAULT_Y_EXPRESSION );
	setComponentFontSize(yExpressionField, fontSize);
	mountComponent( yExpressionField, window );


	int tMaxLabel = newTextLabel( 10, 90, leftWidth, 25, "t-max =" );
	setComponentFontSize(tMaxLabel, fontSize);
	mountComponent( tMaxLabel, window );

	tMaxField = newTextField( rightX, 90, rightWidth, 25, DEFAULT_T_MAX );
	setComponentFontSize(tMaxField, fontSize);
	mountComponent( tMaxField, window );

	int tMinLabel = newTextLabel( 10, 120, leftWidth, 25, "t-min =" );
	setComponentFontSize(tMinLabel, fontSize);
	mountComponent( tMinLabel, window );

	tMinField = newTextField( rightX, 120, rightWidth, 25, DEFAULT_T_MIN );
	setComponentFontSize(tMinField, fontSize);
	mountComponent( tMinField, window );


	int tNLabel = newTextLabel( 10, 150, leftWidth, 25, "t-N =" );
	setComponentFontSize(tNLabel, fontSize);
	mountComponent( tNLabel, window );

	tNField = newTextField( rightX, 150, rightWidth, 25, DEFAULT_T_N );
	setComponentFontSize(tNField, fontSize);
	mountComponent( tNField, window );


	int buttonGridPanel = newGridPanel( 10, 240, buttonWidth, 280, "", 5, 1 );
	mountComponent( buttonGridPanel, window );

	plotButton = newButton( 0, 0, 0, 0, "プロット" );
	setComponentFontSize(plotButton, fontSize);
	mountComponent( plotButton, buttonGridPanel );

	animationButton = newButton( 0, 0, 0, 0, "アニメーション" );
	setComponentFontSize(animationButton, fontSize);
	mountComponent( animationButton, buttonGridPanel );

	clearButton = newButton( 0, 0, 0, 0, "クリア" );
	setComponentFontSize(clearButton, fontSize);
	mountComponent( clearButton, buttonGridPanel );

	exportButton = newButton( 0, 0, 0, 0, "データ出力" );
	setComponentFontSize(exportButton, fontSize);
	mountComponent( exportButton, buttonGridPanel );

	exitButton = newButton( 0, 0, 0, 0, "終了" );
	setComponentFontSize(exitButton, fontSize);
	mountComponent( exitButton, buttonGridPanel );
}


/**
 * 現在のデータをファイルに出力します。
 */
void exportFile(){

	// ファイルパスの選択
	string exportFilePath[] = choose();
	if (length(exportFilePath) == 0) {
		return; // 何も選択されなかった場合
	}

	// 拡張子が無ければ付ける
	string name = getFileName( exportFilePath[0] );
	if( indexOf(name,".") < 0 ){
		exportFilePath += ".dat2d";
	}

	// ファイル出力
	exportGraph2DData(graph, exportFilePath[0], "COLUMN_TSV");

	// 保存完了メッセージを表示
	pop( "SAVED: " + exportFilePath[0] );
}


/**
 * 入力画面上の入力項目において、式として評価するのに適さない文字を、適切な文字で置き換えます。
 */
void correctCharactersOnInputWindow() {
	
	setComponentText(
		xExpressionField, 
		correctCharactersInExpression(
			getComponentText(xExpressionField)
		)
	);
	
	setComponentText(
		yExpressionField, 
		correctCharactersInExpression(
			getComponentText(yExpressionField)
		)
	);
	
	setComponentText(
		tMaxField, 
		correctCharactersInExpression(
			getComponentText(tMaxField)
		)
	);
	
	setComponentText(
		tMinField, 
		correctCharactersInExpression(
			getComponentText(tMinField)
		)
	);
	
	setComponentText(
		tNField, 
		correctCharactersInExpression(
			getComponentText(tNField)
		)
	);
}


/**
 * 文字列内で、式として評価するのに適さない文字を、適切な文字で置き換えます。
 * 
 * @param 式の内容を格納する文字列
 * @return 適切に文字を置き換えた文字列
 */
string correctCharactersInExpression(string expression) {
	string result = expression;
	
	result = replaceText(result, "×", "*", Text.ALL);
	result = replaceText(result, "÷", "/", Text.ALL);
	result = replaceText(result, "＾", "**", Text.ALL);
	result = replaceText(result, "^",  "**", Text.ALL);
	
	result = replaceText(result, "＋", "+", Text.ALL);
	result = replaceText(result, "＊", "*", Text.ALL);
	result = replaceText(result, "／", "/", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "−", "-", Text.ALL);
	result = replaceText(result, "―", "-", Text.ALL);
	result = replaceText(result, "‐", "-", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "％", "%", Text.ALL);
	result = replaceText(result, "（", "(", Text.ALL);
	result = replaceText(result, "）", ")", Text.ALL);
	
	result = replaceText(result, "Ａ", "A", Text.ALL);
	result = replaceText(result, "Ｂ", "B", Text.ALL);
	result = replaceText(result, "Ｃ", "C", Text.ALL);
	result = replaceText(result, "Ｄ", "D", Text.ALL);
	result = replaceText(result, "Ｅ", "E", Text.ALL);
	result = replaceText(result, "Ｆ", "F", Text.ALL);
	result = replaceText(result, "Ｇ", "G", Text.ALL);
	result = replaceText(result, "Ｈ", "H", Text.ALL);
	result = replaceText(result, "Ｉ", "I", Text.ALL);
	result = replaceText(result, "Ｊ", "J", Text.ALL);
	result = replaceText(result, "Ｋ", "K", Text.ALL);
	result = replaceText(result, "Ｌ", "L", Text.ALL);
	result = replaceText(result, "Ｍ", "M", Text.ALL);
	result = replaceText(result, "Ｎ", "N", Text.ALL);
	result = replaceText(result, "Ｏ", "O", Text.ALL);
	result = replaceText(result, "Ｐ", "P", Text.ALL);
	result = replaceText(result, "Ｑ", "Q", Text.ALL);
	result = replaceText(result, "Ｒ", "R", Text.ALL);
	result = replaceText(result, "Ｓ", "S", Text.ALL);
	result = replaceText(result, "Ｔ", "T", Text.ALL);
	result = replaceText(result, "Ｕ", "U", Text.ALL);
	result = replaceText(result, "Ｖ", "V", Text.ALL);
	result = replaceText(result, "Ｗ", "W", Text.ALL);
	result = replaceText(result, "Ｘ", "X", Text.ALL);
	result = replaceText(result, "Ｙ", "Y", Text.ALL);
	result = replaceText(result, "Ｚ", "Z", Text.ALL);
	
	result = replaceText(result, "ａ", "a", Text.ALL);
	result = replaceText(result, "ｂ", "b", Text.ALL);
	result = replaceText(result, "ｃ", "c", Text.ALL);
	result = replaceText(result, "ｄ", "d", Text.ALL);
	result = replaceText(result, "ｅ", "e", Text.ALL);
	result = replaceText(result, "ｆ", "f", Text.ALL);
	result = replaceText(result, "ｇ", "g", Text.ALL);
	result = replaceText(result, "ｈ", "h", Text.ALL);
	result = replaceText(result, "ｉ", "i", Text.ALL);
	result = replaceText(result, "ｊ", "j", Text.ALL);
	result = replaceText(result, "ｋ", "k", Text.ALL);
	result = replaceText(result, "ｌ", "l", Text.ALL);
	result = replaceText(result, "ｍ", "m", Text.ALL);
	result = replaceText(result, "ｎ", "n", Text.ALL);
	result = replaceText(result, "ｏ", "o", Text.ALL);
	result = replaceText(result, "ｐ", "p", Text.ALL);
	result = replaceText(result, "ｑ", "q", Text.ALL);
	result = replaceText(result, "ｒ", "r", Text.ALL);
	result = replaceText(result, "ｓ", "s", Text.ALL);
	result = replaceText(result, "ｔ", "t", Text.ALL);
	result = replaceText(result, "ｕ", "u", Text.ALL);
	result = replaceText(result, "ｖ", "v", Text.ALL);
	result = replaceText(result, "ｗ", "w", Text.ALL);
	result = replaceText(result, "ｘ", "x", Text.ALL);
	result = replaceText(result, "ｙ", "y", Text.ALL);
	result = replaceText(result, "ｚ", "z", Text.ALL);
	
	result = replaceText(result, "１", "1", Text.ALL);
	result = replaceText(result, "２", "2", Text.ALL);
	result = replaceText(result, "３", "3", Text.ALL);
	result = replaceText(result, "４", "4", Text.ALL);
	result = replaceText(result, "５", "5", Text.ALL);
	result = replaceText(result, "６", "6", Text.ALL);
	result = replaceText(result, "７", "7", Text.ALL);
	result = replaceText(result, "８", "8", Text.ALL);
	result = replaceText(result, "９", "9", Text.ALL);
	result = replaceText(result, "０", "0", Text.ALL);
	result = replaceText(result, "．", ".", Text.ALL);
	
	return result;
}


/**
 * ボタンが押された際にコールされます（イベントハンドラ）
 * 
 * @param id 押されたボタンのID
 */
void onButtonClick( int id ){

	// 「PLOT」ボタンが押された場合
	if( id == plotButton ){

		// 画面上に入力されている文字列内で、式として評価するのに適さない文字を、適切な文字で置き換え
		correctCharactersOnInputWindow();

		// 以下、画面から入力内容を取得

		// 入力された x, y の数式を取得
		string xExpression = getComponentText( xExpressionField );
		string yExpression = getComponentText( yExpressionField );

		// t の範囲の最大・最小値やプロット点数の入力内容が、文法的に正しいか検査
		if( !evaluable( getComponentText( tMaxField ), 0.0 ) ){
			alert("t-maxの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( tMinField ), 0.0 ) ){
			alert("t-minの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( tNField ), 0.0 ) ){
			alert("t-Nの式に誤りがあります。");
			return;
		}

		// t の範囲の最大・最小値やプロット点数の入力内容を解釈し、値を求める
		float tMax = feval( getComponentText( tMaxField ), 0.0 );
		float tMin = feval( getComponentText( tMinField ), 0.0 );
		int tN = feval( getComponentText( tNField ), 0.0 );

		// x, y の数式をグラフにプロットする（plotGraph関数はこのファイル内の上の方で定義）
		plotGraph( xExpression, yExpression, tMax, tMin, tN );
		return;
	}

	// 「CLEAR」ボタンが押された場合
	if( id == clearButton ){
		clearGraph2D(graph);
		return;
	}

	// 「ANIMATION」ボタンが押された場合
	if( id == animationButton ){
		setGraph2DAnimation( graph, "TRACE", true );
		return;
	}

	// 「EXPORT」ボタンが押された場合
	if( id == exportButton ){
		exportFile();
		return;
	}

	// 「EXIT」ボタンが押された場合
	if( id == exitButton ){
		exit();
		return;
	}
}


/**
 * ウィンドウが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたウィンドウのID
 */
void onWindowClose( int id ){
	if( id == window ){
		exit();
		return;
	}
}


/**
 * グラフが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたグラフのID
 */
void onGraph2DClose( int id ){
	if( id == graph ){
		exit();
		return;
	}
}