coding Shift_JIS;

import Math;
import Text;
import GUI;
import File;
import tool.Graph2D;


/** グラフに描画する数式 y(x) のデフォルト入力値です。 */
const string DEFAULT_Y_EXPRESSION = "sin(3*x)";

/** グラフのX範囲の最大値（右端）のデフォルト入力値です。 */
const string DEFAULT_X_MAX = "1.0";

/** グラフのX範囲の最小値（左端）のデフォルト入力値です。 */
const string DEFAULT_X_MIN = "-1.0";

/** グラフのプロット点数のデフォルト入力値です。 */
const string DEFAULT_X_N = "100";



// 以下、グラフやGUIコンポーネントIDを格納する変数

/** グラフのIDを格納します。 **/
int graph = NULL;

/** 入力画面のウィンドウのIDを格納します。 */
int window = NULL;

/** y(x) の数式を入力するテキストフィールドのIDを格納します。 */
int expressionField = NULL;

/** X軸の最大値を入力するテキストフィールドのIDを格納します。 */
int xMaxField = NULL;

/** X軸の最小値を入力するテキストフィールドのIDを格納します。 */
int xMinField = NULL;

/** グラフのプロット点数を入力するテキストフィールドのIDを格納します。 */
int xNField = NULL;

/** PLOTボタンのIDを格納します。 */
int plotButton = NULL;

/** CLEARボタンのIDを格納します。 */
int clearButton = NULL;

/** EXPORTボタンのIDを格納します。 */
int exportButton = NULL;

/** EXITボタンのIDを格納します。 */
int exitButton = NULL;



/**
 * プログラムの開始時に自動で実行されます。
 */
void main(){

	// GUIを備えたツールではコンソール画面は邪魔なので非表示化
	hide();

	// システム側で標準接続されている2DグラフソフトがあればIDを取得（無ければnewGraph2D関数同様、新規に立ち上がる）
	graph = getGraph2D();

	// ※ 普通に newGraph2D 関数で新規生成しないのは、このプログラムがリニアングラフ2Dにも同梱されるツールであり、
	//    リニアングラフ2D上でメニューからこのプログラムを実行した際に、そのグラフ自身を制御対象とするためです。

	// グラフ画面の位置とサイズを設定
	setGraph2DLocation(graph, 330, 0);
	setGraph2DSize(graph, 720, 600);

	// 入力画面を起動
	createInputWindow();

	// ※ ユーザーがボタンを押すとグラフが描かれる処理などは、
	//    後方の onButtonClick 関数を起点として実行されます。
}


/**
 * 引数に指定された数式をグラフにプロットします。
 * 
 * @param yExpression プロットするyの数式(xの関数)
 * @param xMin x軸の最小値
 * @param xMax x軸の最大値
 * @param n プロット点数
 */
void plotGraph( string yExpression, double xMin, double xMax, int n ){

	// グラフに転送するデータ配列
	double xArray[n];
	double yArray[n];

	// グラフを構成する点の X, Y 座標を格納する変数
	//（入力された y の数式の中でも変数 x は参照するので、スコープの都合上ここで宣言）
	double x;
	double y;

	//  y の数式が文法的に正しいか検査
	if( !evaluable(yExpression, 0.0) ){
		alert("y(x)の式に誤りがあります。");
		return;
	}

	// xをx軸上でn分割した点において、数式からyの値を求め、配列に格納
	float dx = (xMax-xMin)/(n-1);
	for( int i=0; i<n; i++ ){
		x = xMin + i * dx;
		
		// 文字列の式を解釈してfloatの値を得る（第2引数は式内の整数を浮動小数点数と見なすオプション）
		y = feval( yExpression, 0.0 );
		
		xArray[ i ] = x;
		yArray[ i ] = y;
	}

	// 配列をグラフソフトウェアに転送し、プロット
	addGraph2DData( graph, xArray, yArray );
}


/**
 * 数式などを入力する、入力画面のGUIを構築して起動します。
 */
void createInputWindow(){

	int leftWidth = 100;
	int rightX = leftWidth + 10;
	int rightWidth = 170;
	int buttonWidth = 270;
	int fontSize = 20;
	
	window = newWindow( 0, 0, 320, 460, "入力画面" );

	int expressionLabel = newTextLabel( 10, 10, leftWidth, 25, "y( x ) =" );
	setComponentFontSize(expressionLabel, fontSize);
	mountComponent( expressionLabel, window );

	expressionField = newTextField( rightX, 10, rightWidth, 25, DEFAULT_Y_EXPRESSION );
	setComponentFontSize(expressionField, fontSize);
	mountComponent( expressionField, window );

	int xMaxLabel = newTextLabel( 10, 60, leftWidth, 25, "x-max =" );
	setComponentFontSize(xMaxLabel, fontSize);
	mountComponent( xMaxLabel, window );

	xMaxField = newTextField( rightX, 60, rightWidth, 25, DEFAULT_X_MAX );
	setComponentFontSize(xMaxField, fontSize);
	mountComponent( xMaxField, window );

	int xMinLabel = newTextLabel( 10, 90, leftWidth, 25, "x-min =" );
	setComponentFontSize(xMinLabel, fontSize);
	mountComponent( xMinLabel, window );

	xMinField = newTextField( rightX, 90, rightWidth, 25, DEFAULT_X_MIN );
	setComponentFontSize(xMinField, fontSize);
	mountComponent( xMinField, window );


	int xNLabel = newTextLabel( 10, 120, leftWidth, 25, "x-N =" );
	setComponentFontSize(xNLabel, fontSize);
	mountComponent( xNLabel, window );

	xNField = newTextField( rightX, 120, rightWidth, 25, DEFAULT_X_N );
	setComponentFontSize(xNField, fontSize);
	mountComponent( xNField, window );


	plotButton = newButton( 10, 160, buttonWidth, 50, "プロット" );
	setComponentFontSize(plotButton, fontSize);
	mountComponent( plotButton, window );


	clearButton = newButton( 10, 220, buttonWidth, 50, "クリア" );
	setComponentFontSize(clearButton, fontSize);
	mountComponent( clearButton, window );

	exportButton = newButton( 10, 280, buttonWidth, 50, "データ出力" );
	setComponentFontSize(exportButton, fontSize);
	mountComponent( exportButton, window );

	exitButton = newButton( 10, 340, buttonWidth, 50, "終了" );
	setComponentFontSize(exitButton, fontSize);
	mountComponent( exitButton, window );
}


/**
 * 現在のデータをファイルに出力します。
 */
void exportFile(){

	// ファイルパスの選択
	string exportFilePath[] = choose();
	if (length(exportFilePath) == 0) {
		return; // 何も選択されなかった場合
	}

	// 拡張子が無ければ付ける
	string name = getFileName( exportFilePath[0] );
	if( indexOf(name,".") < 0 ){
		exportFilePath += ".dat2d";
	}

	// ファイル出力
	exportGraph2DData(graph, exportFilePath[0], "COLUMN_TSV");

	// 保存完了メッセージを表示
	pop( "SAVED: " + exportFilePath[0] );
}


/**
 * 入力画面上の入力項目において、式として評価するのに適さない文字を、適切な文字で置き換えます。
 */
void correctCharactersOnInputWindow() {
	
	setComponentText(
		expressionField, 
		correctCharactersInExpression(
			getComponentText(expressionField)
		)
	);
	
	setComponentText(
		xMaxField, 
		correctCharactersInExpression(
			getComponentText(xMaxField)
		)
	);
	
	setComponentText(
		xMinField, 
		correctCharactersInExpression(
			getComponentText(xMinField)
		)
	);
	
	setComponentText(
		xNField, 
		correctCharactersInExpression(
			getComponentText(xNField)
		)
	);
}


/**
 * 文字列内で、式として評価するのに適さない文字を、適切な文字で置き換えます。
 * 
 * @param 式の内容を格納する文字列
 * @return 適切に文字を置き換えた文字列
 */
string correctCharactersInExpression(string expression) {
	string result = expression;
	
	result = replaceText(result, "×", "*", Text.ALL);
	result = replaceText(result, "÷", "/", Text.ALL);
	result = replaceText(result, "＾", "**", Text.ALL);
	result = replaceText(result, "^",  "**", Text.ALL);
	
	result = replaceText(result, "＋", "+", Text.ALL);
	result = replaceText(result, "＊", "*", Text.ALL);
	result = replaceText(result, "／", "/", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "−", "-", Text.ALL);
	result = replaceText(result, "―", "-", Text.ALL);
	result = replaceText(result, "‐", "-", Text.ALL);
	result = replaceText(result, "ー", "-", Text.ALL);
	result = replaceText(result, "％", "%", Text.ALL);
	result = replaceText(result, "（", "(", Text.ALL);
	result = replaceText(result, "）", ")", Text.ALL);
	
	result = replaceText(result, "Ａ", "A", Text.ALL);
	result = replaceText(result, "Ｂ", "B", Text.ALL);
	result = replaceText(result, "Ｃ", "C", Text.ALL);
	result = replaceText(result, "Ｄ", "D", Text.ALL);
	result = replaceText(result, "Ｅ", "E", Text.ALL);
	result = replaceText(result, "Ｆ", "F", Text.ALL);
	result = replaceText(result, "Ｇ", "G", Text.ALL);
	result = replaceText(result, "Ｈ", "H", Text.ALL);
	result = replaceText(result, "Ｉ", "I", Text.ALL);
	result = replaceText(result, "Ｊ", "J", Text.ALL);
	result = replaceText(result, "Ｋ", "K", Text.ALL);
	result = replaceText(result, "Ｌ", "L", Text.ALL);
	result = replaceText(result, "Ｍ", "M", Text.ALL);
	result = replaceText(result, "Ｎ", "N", Text.ALL);
	result = replaceText(result, "Ｏ", "O", Text.ALL);
	result = replaceText(result, "Ｐ", "P", Text.ALL);
	result = replaceText(result, "Ｑ", "Q", Text.ALL);
	result = replaceText(result, "Ｒ", "R", Text.ALL);
	result = replaceText(result, "Ｓ", "S", Text.ALL);
	result = replaceText(result, "Ｔ", "T", Text.ALL);
	result = replaceText(result, "Ｕ", "U", Text.ALL);
	result = replaceText(result, "Ｖ", "V", Text.ALL);
	result = replaceText(result, "Ｗ", "W", Text.ALL);
	result = replaceText(result, "Ｘ", "X", Text.ALL);
	result = replaceText(result, "Ｙ", "Y", Text.ALL);
	result = replaceText(result, "Ｚ", "Z", Text.ALL);
	
	result = replaceText(result, "ａ", "a", Text.ALL);
	result = replaceText(result, "ｂ", "b", Text.ALL);
	result = replaceText(result, "ｃ", "c", Text.ALL);
	result = replaceText(result, "ｄ", "d", Text.ALL);
	result = replaceText(result, "ｅ", "e", Text.ALL);
	result = replaceText(result, "ｆ", "f", Text.ALL);
	result = replaceText(result, "ｇ", "g", Text.ALL);
	result = replaceText(result, "ｈ", "h", Text.ALL);
	result = replaceText(result, "ｉ", "i", Text.ALL);
	result = replaceText(result, "ｊ", "j", Text.ALL);
	result = replaceText(result, "ｋ", "k", Text.ALL);
	result = replaceText(result, "ｌ", "l", Text.ALL);
	result = replaceText(result, "ｍ", "m", Text.ALL);
	result = replaceText(result, "ｎ", "n", Text.ALL);
	result = replaceText(result, "ｏ", "o", Text.ALL);
	result = replaceText(result, "ｐ", "p", Text.ALL);
	result = replaceText(result, "ｑ", "q", Text.ALL);
	result = replaceText(result, "ｒ", "r", Text.ALL);
	result = replaceText(result, "ｓ", "s", Text.ALL);
	result = replaceText(result, "ｔ", "t", Text.ALL);
	result = replaceText(result, "ｕ", "u", Text.ALL);
	result = replaceText(result, "ｖ", "v", Text.ALL);
	result = replaceText(result, "ｗ", "w", Text.ALL);
	result = replaceText(result, "ｘ", "x", Text.ALL);
	result = replaceText(result, "ｙ", "y", Text.ALL);
	result = replaceText(result, "ｚ", "z", Text.ALL);
	
	result = replaceText(result, "１", "1", Text.ALL);
	result = replaceText(result, "２", "2", Text.ALL);
	result = replaceText(result, "３", "3", Text.ALL);
	result = replaceText(result, "４", "4", Text.ALL);
	result = replaceText(result, "５", "5", Text.ALL);
	result = replaceText(result, "６", "6", Text.ALL);
	result = replaceText(result, "７", "7", Text.ALL);
	result = replaceText(result, "８", "8", Text.ALL);
	result = replaceText(result, "９", "9", Text.ALL);
	result = replaceText(result, "０", "0", Text.ALL);
	result = replaceText(result, "．", ".", Text.ALL);
	
	return result;
}


/**
 * ボタンが押された際にコールされます（イベントハンドラ）
 * 
 * @param id 押されたボタンのID
 */
void onButtonClick( int id ){

	// 「PLOT」ボタンが押された場合
	if( id == plotButton ){

		// 画面上に入力されている文字列内で、式として評価するのに適さない文字を、適切な文字で置き換え
		correctCharactersOnInputWindow();

		// 以下、画面から入力内容を取得

		// 入力された y の数式を取得
		string yExpression = getComponentText( expressionField );

		// X範囲の最大・最小値やプロット点数の入力内容が、文法的に正しいか検査
		if( !evaluable( getComponentText( xMaxField ), 0.0 ) ){
			alert("x-maxの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( xMinField ), 0.0 ) ){
			alert("x-minの式に誤りがあります。");
			return;
		}
		if( !evaluable( getComponentText( xNField ), 0.0 ) ){
			alert("x-Nの式に誤りがあります。");
			return;
		}

		// X範囲の最大・最小値やプロット点数の入力内容を解釈し、値を求める
		double xMax = feval( getComponentText( xMaxField ), 0.0 );
		double xMin = feval( getComponentText( xMinField ), 0.0 );
		int xN = feval( getComponentText( xNField ), 0.0 );

		// y の数式をグラフにプロットする（plotGraph関数はこのファイル内の上の方で定義）
		plotGraph( yExpression, xMin, xMax, xN );
		return;
	}

	// 「CLEAR」ボタンが押された場合
	if( id == clearButton ){
		clearGraph2D(graph);
		return;
	}

	// 「EXPORT」ボタンが押された場合
	if( id == exportButton ){
		exportFile();
		return;
	}

	// 「EXIT」ボタンが押された場合
	if( id == exitButton ){
		exit();
		return;
	}
}


/**
 * ウィンドウが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたウィンドウのID
 */
void onWindowClose( int id ){
	if( id == window ){
		exit();
		return;
	}
}


/**
 * グラフが閉じられた際にコールされます（イベントハンドラ）
 * 
 * @param id 閉じられたグラフのID
 */
void onGraph2DClose( int id ){
	if( id == graph ){
		exit();
		return;
	}
}