coding Shift_JIS;

import GUI;
import Math;
import tool.Graph3D;


// ==================================================
// このプログラムは、ローレンツ方程式を
// RK4（4次収束ルンゲ=クッタ）法で
// 数値積分するプログラムです。
// 描かれる曲線は
// 「ローレンツアトラクタ」として有名です。
// ==================================================




// 軌道の形を左右するパラメータ
double PARAM_S = 10.0;
double PARAM_B = 4.0;
double PARAM_R = 100.0;


const int N = 3000;  // グラフ点数
const int ROOP_PER_POINT = 30; // 1点ごとに何ループ計算するか
const double DT = 0.0001;  //1ループごとの時間進行量


// 軌道の座標
double orbitX[ N ];
double orbitY[ N ];
double orbitZ[ N ];


// メインループのON/OFF制御変数
bool mainLoopState = true;

// 再プロットが必要なときにONにする変数
bool plotRequest = true;


int graph;


// ==================================================
// メイン処理、この関数は起動時に自動的に呼ばれる
// ==================================================

void main( string args[] ){

  // 設定画面を起動
  createSettingWindow();

  // 3Dグラフソフトを起動
  graph = newGraph3D( 0, 0, 700, 580, "Graph Window" );
  setGraph3DOption( graph, "WITH_LINES", true );


  // RK4法で軌道を計算するための変数
  double x, y, z;
  double k1_x, k1_y, k1_z;
  double k2_x, k2_y, k2_z;
  double k3_x, k3_y, k3_z;
  double k4_x, k4_y, k4_z;
  double x_stock, y_stock, z_stock;



  // プログラム終了時まで繰り返すループ（メインループ）
  while( mainLoopState ){



    // リクエストがあれば、軌道を計算して再プロット
    if( plotRequest ){

      plotRequest = false;

      // 初期座標をセット
      x = 0.1;
      y = 0.1;
      z = 0.1;

      int plotIndex = 0;

      // 軌道を計算
      for( int i=0; i<N*ROOP_PER_POINT; i++ ){

        // RK4法（4時収束ルンゲ=クッタ法）による軌道計算
        k1_x = f_x( x, y, z );
        k1_y = f_y( x, y, z );
        k1_z = f_z( x, y, z );

        k2_x = f_x( x+k1_x*DT*0.5, y+k1_y*DT*0.5, z+k1_z*DT*0.5 );
        k2_y = f_y( x+k1_x*DT*0.5, y+k1_y*DT*0.5, z+k1_z*DT*0.5 );
        k2_z = f_z( x+k1_x*DT*0.5, y+k1_y*DT*0.5, z+k1_z*DT*0.5 );

        k3_x = f_x( x+k2_x*DT*0.5, y+k2_y*DT*0.5, z+k2_z*DT*0.5 );
        k3_y = f_y( x+k2_x*DT*0.5, y+k2_y*DT*0.5, z+k2_z*DT*0.5 );
        k3_z = f_z( x+k2_x*DT*0.5, y+k2_y*DT*0.5, z+k2_z*DT*0.5 );

        k4_x = f_x( x+k3_x*DT, y+k3_y*DT, z+k3_z*DT );
        k4_y = f_y( x+k3_x*DT, y+k3_y*DT, z+k3_z*DT );
        k4_z = f_z( x+k3_x*DT, y+k3_y*DT, z+k3_z*DT );

        x += ( k1_x + 2.0*k2_x + 2.0*k3_x + k4_x )*DT/6.0;
        y += ( k1_y + 2.0*k2_y + 2.0*k3_y + k4_y )*DT/6.0;
        z += ( k1_z + 2.0*k2_z + 2.0*k3_z + k4_z )*DT/6.0;

		if( i % ROOP_PER_POINT == 0 ){
          orbitX[ plotIndex ] = x;
          orbitY[ plotIndex ] = y;
          orbitZ[ plotIndex ] = z;
          plotIndex++;
        }

      }

      // グラフソフトにデータを転送
      setGraph3DData( graph, orbitX, orbitY, orbitZ );

    }else{

      // リクエストが無い場合は、何もせず100ミリ秒休止
      sleep( 100 );

    }


  }

  exit(); // メインループを脱出すると実行終了

}



// x方向の変化率を与える関数（高速化のためマクロを使用）
macro f_x( float X, float Y, float Z ){
	return -PARAM_S*X + PARAM_S*Y;
}

// y方向の変化率を与える関数（高速化のためマクロを使用）
macro f_y( float X, float Y, float Z ){
	return -X*Z + PARAM_R*X - Y;
}

// z方向の変化率を与える関数（高速化のためマクロを使用）
macro f_z( float X, float Y, float Z ){
	return X*Y - PARAM_B*Z;
}











int WINDOW;
int PARAM_S_SLIDER, PARAM_B_SLIDER, PARAM_R_SLIDER;
int PARAM_S_LABEL, PARAM_B_LABEL, PARAM_R_LABEL;
int END_BUTTON, ANIMATION_BUTTON;


// ==================================================
// 設定ウィンドウを生成する関数
// ==================================================

void createSettingWindow(){

  WINDOW = newWindow( 0, 580, 700, 220, "Setting Window" );

  int explainLabel1 = newTextLabel( 10, 10, 480, 15, "dx / dt = - S * x + S * y" );
  mountComponent( explainLabel1, WINDOW );
  int explainLabel2 = newTextLabel( 10, 25, 480, 15, "dy / dt = - x * z + R * x - y" );
  mountComponent( explainLabel2, WINDOW );
  int explainLabel3 = newTextLabel( 10, 40, 480, 15, "dz / dt = x * y - B * z" );
  mountComponent( explainLabel3, WINDOW );


  PARAM_S_LABEL = newTextLabel( 10, 60, 480, 15, "S = "+PARAM_S );
  mountComponent( PARAM_S_LABEL, WINDOW );
  PARAM_S_SLIDER = newHorizontalSlider( 10, 75, 480, 15, PARAM_S/50.0 );
  mountComponent( PARAM_S_SLIDER, WINDOW );

  PARAM_B_LABEL = newTextLabel( 10, 90, 400, 15, "B = "+PARAM_B );
  mountComponent( PARAM_B_LABEL, WINDOW );
  PARAM_B_SLIDER = newHorizontalSlider( 10, 105, 480, 15, PARAM_B/50.0 );
  mountComponent( PARAM_B_SLIDER, WINDOW );

  PARAM_R_LABEL = newTextLabel( 10, 120, 400, 15, "R ="+PARAM_R );
  mountComponent( PARAM_R_LABEL, WINDOW );
  PARAM_R_SLIDER = newHorizontalSlider( 10, 135, 480, 15, PARAM_R/500.0 );
  mountComponent( PARAM_R_SLIDER, WINDOW );

  ANIMATION_BUTTON = newButton( 500, 10, 150, 60, "ANIMATION" );
  setComponentFontSize( ANIMATION_BUTTON, 18 );
  mountComponent( ANIMATION_BUTTON, WINDOW );

  END_BUTTON = newButton( 500, 90, 150, 60, "EXIT" );
  setComponentFontSize( END_BUTTON, 18 );
  mountComponent( END_BUTTON, WINDOW );



  paintComponent( WINDOW );

}





// ==================================================
// スライダーが動いた際に呼ばれる関数（イベントハンドラ）
// ==================================================

void onSliderMove( int id, float value ){

  if( id==PARAM_S_SLIDER ){

    PARAM_S = value * 50.0;
    setComponentText( PARAM_S_LABEL, "S = "+PARAM_S );
    paintComponent( PARAM_S_LABEL );

  }else if( id==PARAM_B_SLIDER ){

    PARAM_B = value * 50.0;
    setComponentText( PARAM_B_LABEL, "B = "+PARAM_B );
    paintComponent( PARAM_B_LABEL );

  }else if( id==PARAM_R_SLIDER ){

    PARAM_R = value * 500.0;
    setComponentText( PARAM_R_LABEL, "R = "+PARAM_R );
    paintComponent( PARAM_R_LABEL );

  }
  paintComponent( WINDOW );

  plotRequest = true;

}






// ==================================================
// ボタンが押された際に呼ばれる関数（イベントハンドラ）
// ==================================================

void onButtonClick( int id ){
  if( id == ANIMATION_BUTTON ){
    setGraph3DAnimation( graph, "TRACE", true );
  }
  if( id == END_BUTTON ){
    mainLoopState = false;
  }
}


// ==================================================
// ウィンドウが閉じられた際に呼ばれる関数（イベントハンドラ）
// ==================================================

void onWindowClose( int ID ){

  mainLoopState = false;

}