coding UTF-8;

// Load libraries.
import Math;
import GUI;
import tool.Graph3D;


// Parameters of the wave.
double amplitude = 0.85;
double wavelength = 2.0;
double period = 1.5;

// Paerameters for plotting the graph.
const int N = 100;           // The number of grid points, for X/Y directions of the 3D mesh.
const double X_MIN = -5.0;   // The min value of the x-axis of the graph.
const double X_MAX = 5.0;    // The max value of the x-axis of the graph.
const double Y_MIN = -5.0;   // The min value of the y-axis of the graph.
const double Y_MAX = 5.0;    // The max value of the y-axis of the graph.
const double Z_MIN = -1.0;   // The min value of the z-axis of the graph.
const double Z_MAX = 1.0;    // The max value of the z-axis of the graph.
const double DT = 0.1;       // One step of the discrete time (when the speed=1.0)
const double DX = (X_MAX - X_MIN) / (N-1); // One step of the discrete x values.
const double DY = (Y_MAX - Y_MIN) / (N-1); // One step of the discrete y values.

// Arrays storing x/y/z coordinates of the grid points of the 3D mesh, for plotting the graph.
double waveX[ N ][ N ];
double waveY[ N ][ N ];
double waveZ[ N ][ N ];

// Variables for storing IDs of tje GUI components.
int window;
int periodSlider;
int wavelengthSlider;
int amplitudeSlider;
int speedSlider;
int infoLabel;
int timeLabel;
int resetButton;

// Other variables.
float speed = 0.7;         // The speed of the animation.
int graph;                 // Stores ID of the 3D graph software (RINEARN Graph 3D).
bool continuesLoop = true; // The flag representing whether the main loop continues/exits.
double t;                  // The variable representing time.


// ================================================================================
// The main function, which will be invoked automatically when the program starts.
// ================================================================================

void main( ){

	// Launch the 3D graph software (RINEARN Graph 3D).
	createGraphWindow();

	// Create the window, and initializes the GUI components.
	createSettingWindow();

	// The main loop.
	t = 0.0;
	while( continuesLoop ) {

		// Compute coordinates of grid points of the 3D mesh to be plotted on the graph.
		for( int yi=0; yi<N; yi++ ) {
			for( int xi=0; xi<N; xi++ ) {

				double x = X_MIN + xi * DX; // The x coord of the xi-th point for x direction.
				double y = Y_MIN + yi * DY; // The y coord of the yi-th point for y direction.
				double r = sqrt(x*x + y*y); // The horizontal distance from the origin of the x-y plane.

				// Compute the x/y/z coordinates of the grid point at (ix,iy) of the 3D mesh.
				waveX[yi][xi] = x;
				waveY[yi][xi] = y;
				waveZ[yi][xi] = amplitude * sin( 2.0 * PI * ( t/period - r/wavelength ) );
			}
		}

		// Transfer the above to the graph software.
		setGraph3DData( graph, waveX, waveY, waveZ );

		// Set the next discrete time to the time variable t.
		t += DT * speed;

		// Wait 30 milliseconds.
		sleep( 30 );
	}

	// Exit this program when the flow breaks from the main loop.
	exit();
}


// ================================================================================
// The function launching graph software and initializing it.
// ================================================================================

void createGraphWindow() {

	// Launch the 3D graph software (RINEARN Graph 3D).
	graph = newGraph3D( 0, 0, 800, 600, "Graph Window" );

	// Load the pre-saved setting file.
	setGraph3DConfigurationFile(graph, "RinearnGraph3DSetting.ini");

	// Disable the feature for adjusting x/y ranges automatically, 
	// and set the ranges explicitly.
	setGraph3DAutoRange( graph, false, false, false );
	setGraph3DRange( graph, X_MIN, X_MAX, Y_MIN, Y_MAX, Z_MIN, Z_MAX );
	
	// Enable/disable some plotting options.
	setGraph3DOption(graph, "WITH_POINTS", false);
	setGraph3DOption(graph, "WITH_MEMBRANES", true);
}


// ================================================================================
// The function creating the window and initializing the GUI components.
// ================================================================================

void createSettingWindow() {

	// Create a window.
	window = newWindow( 0, 600, 800, 230, "Setting Window" );

	// Create a label for displaying the value of the time variable t.
	timeLabel = newTextLabel( 10, 10, 200, 20, "" );
	mountComponent( timeLabel, window );

	// Create a slider (range: 0.0 to 1.0) for controling the value of the amplitude.
	amplitudeSlider = newHorizontalSlider( 230, 40, 500, 20, amplitude, 0.0, 1.0 );
	mountComponent( amplitudeSlider, window );
	int amplitudeLabel = newTextLabel( 45, 40, 180, 15, " Amplitude: A (0～1)" );
	mountComponent( amplitudeLabel, window );

	// Create a slider (range: 0.2 to 10.0) for controling the value of the period.
	periodSlider = newHorizontalSlider( 230, 60, 500, 20, period, 0.2, 10.0 );
	mountComponent( periodSlider, window );
	int periodLabel = newTextLabel( 45, 60, 180, 15, "Period: T (0.2～10)" );
	mountComponent( periodLabel, window );

	// Create a slider (range: 0.5 to 8.0) for controling the value of the wavelength.
	wavelengthSlider = newHorizontalSlider( 230, 80, 500, 20, wavelength, 0.5, 8.0 );
	mountComponent( wavelengthSlider, window );
	int wavelengthLabel = newTextLabel( 45, 80, 180, 15, "Wavelength: λ (0.5～8)" );
	mountComponent( wavelengthLabel, window );

	// Create a for displaying the amplitude, wavelength, and period.
	infoLabel = newTextLabel( 230, 100, 400, 20, "" );	
	mountComponent( infoLabel, window );
	updateInfoLabel();

	// Create a slider for controling the animation speed.
	int speedLabel = newTextLabel( 45, 140, 180, 15, "Animation Speed" );
	mountComponent( speedLabel, window );
	speedSlider = newHorizontalSlider( 230, 140, 300, 20, speed, 0.0, 1.0 );
	mountComponent( speedSlider, window );

	// Create a button for resetting the time variable.
	resetButton = newButton(600, 125, 150, 40, "Reset Time");
	mountComponent( resetButton, window );

	// Update the displayed contents of the window.
	paintComponent( window );
}


// ================================================================================
// The function for updating the content displayed in the label above the slider.
// ================================================================================

void updateInfoLabel() {
	string infoText
		= "( A="
		+ round(amplitude, 2, HALF_UP)
		+ ", λ="
		+ round(wavelength, 2, HALF_UP)
		+ ", T="
		+ round(period, 2, HALF_UP)
		+ ")";

	setComponentString(infoLabel, infoText);
	paintComponent(infoLabel);
	paintComponent(window);
}


// ================================================================================
// The function which will be invoked when any slider is moved.
// ================================================================================

void onSliderMove(int id, float value) {

	// Update values of the amplitude, period, wavelength, and the animation speed.
	if(id == amplitudeSlider) {
		amplitude = value;
	}
	if(id == periodSlider) {
		period = value;
	}
	if(id == wavelengthSlider) {
		wavelength = value;
	}
	if (id == speedSlider) {
		speed = value;
	}

	// Update the content of the label displaying the above wave parameters.
	updateInfoLabel();
}


// ================================================================================
// The function which will be invoked when any button is clicked.
// ================================================================================

void onButtonClick(int id) {

	// If the reset button is clicked, reset the value of the time variable t.
	if (id == resetButton) {
		t = 0.0;
	}
}


// ================================================================================
// The function which will be invoked when the window is closed.
// ================================================================================

void onWindowClose(int id) {

	// Break the main loop for terminating this program.
	continuesLoop = false;
}


// ================================================================================
// The function which will be invoked when the graph softoware's window is closed.
// ================================================================================

void onGraph3DClose(int id) {

	// Break the main loop for terminating this program.
	continuesLoop = false;
}