coding UTF-8;

// Load libraries.
import Math;
import GUI;
import tool.Graph2D;


// Parameters of the wave.
double amplitude = 1.0;
double wavelength = 1.0;
double period = 1.0;

// Paerameters for plotting the graph.
const int N = 1024;          // The number of points.
const double X_MIN = 0.0;    // The min value of the x-axis of the graph.
const double X_MAX = 4.0;    // The max value of the x-axis of the graph.
const double Y_MIN = -1.0;   // The min value of the y-axis of the graph.
const double Y_MAX = 1.0;    // The min value of the y-axis of the graph.
const double DT = 0.05;      // One step of the discrete time (when the speed=1.0)
const double DX = (X_MAX - X_MIN) / N; // One step of the discrete x values.

// Arrays storing x and y coordinates of points, for plotting the graph
double waveX[ N ];
double waveY[ N ];

// Variables for storing IDs of tje GUI components.
int window;
int periodSlider;
int wavelengthSlider;
int amplitudeSlider;
int speedSlider;
int infoLabel;
int timeLabel;
int resetButton;

// Other variables.
float speed = 1.0;         // The speed of the animation.
int graph;                 // Stores ID of the 2D graph software (RINEARN Graph 2D).
bool continuesLoop = true; // The flag representing whether the main loop continues/exits.
double t;                  // The variable representing time.


// ================================================================================
// The main function, which will be invoked automatically when the program starts.
// ================================================================================

void main( ){

	// Ask the user whether input params of the wave, and input them if necessary.
	inputParameters();

	// Launch the 2D graph software (RINEARN Graph 2D).
	createGraphWindow();

	// Create the window, and initializes the GUI components.
	createSettingWindow();

	// The main loop.
	t = 0.0;
	while( continuesLoop ) {

		// Display time on the graph.
		string roundedTime = round(t, 1, HALF_UP);
		setGraph2DTitle(graph, "t = " + roundedTime);

		// Compute coords of points to be plotted on the graph.
		for( int i=0; i<N; i++ ) {
			double x = X_MIN + i * DX; // The x coord of the i-th point.
			waveX[ i ] = x;
			waveY[ i ] = amplitude * sin( 2.0 * PI * ( t/period - x/wavelength ) );
		}

		// Transfer the above to the graph software.
		setGraph2DData( graph, waveX, waveY );

		// Set the next discrete time to the time variable t.
		t += DT * speed;

		// Wait 30 milliseconds.
		sleep( 30 );
	}

	// Exit this program when the flow breaks from the main loop.
	exit();
}


// ================================================================================
// The function which requests the user to input parameters.
// ================================================================================

void inputParameters() {
	if ( confirm("Do you want to input the parameters of the sine wave?") ) {
		amplitude = input("Amplitude =", amplitude);
		wavelength = input("Wavelength =", wavelength);
		period = input("Period =", period);
	}
}


// ================================================================================
// The function launching graph software and initializing it.
// ================================================================================

void createGraphWindow() {

	// Launch the 2D graph software (RINEARN Graph 2D).
	graph = newGraph2D( 0, 0, 800, 500, "Graph Window" );

	// Disable the feature for adjusting x/y ranges automatically, 
	// and set the ranges explicitly.
	setGraph2DAutoRange( graph, false, false );
	setGraph2DRange( graph, X_MIN, X_MAX, Y_MIN, Y_MAX );

	// Enable/disable some plotting options.
	setGraph2DOption(graph, "WITH_POINTS", false);
	setGraph2DOption(graph, "WITH_LINES", true);

	// Set of the graph title and the labels of x/y axes.
	setGraph2DLabel( graph, "x", "A sin 2π( t / T - x / λ )" );
}


// ================================================================================
// The function creating the window and initializing the GUI components.
// ================================================================================

void createSettingWindow() {

	// Create a window.
	window = newWindow( 0, 500, 800, 230, "Setting Window" );

	// Create a label for displaying the value of the time variable t.
	timeLabel = newTextLabel( 10, 10, 200, 20, "" );
	mountComponent( timeLabel, window );

	// Create a slider (range: 0.0 to 1.0) for controling the value of the amplitude.
	amplitudeSlider = newHorizontalSlider( 230, 40, 500, 20, amplitude, 0.0, 1.0 );
	mountComponent( amplitudeSlider, window );
	int amplitudeLabel = newTextLabel( 45, 40, 180, 15, " Amplitude: A (0～1)" );
	mountComponent( amplitudeLabel, window );

	// Create a slider (range: 0.2 to 10.0) for controling the value of the period.
	periodSlider = newHorizontalSlider( 230, 60, 500, 20, period, 0.2, 10.0 );
	mountComponent( periodSlider, window );
	int periodLabel = newTextLabel( 45, 60, 180, 15, "Period: T (0.2～10)" );
	mountComponent( periodLabel, window );

	// Create a slider (range: 0.5 to 8.0) for controling the value of the wavelength.
	wavelengthSlider = newHorizontalSlider( 230, 80, 500, 20, wavelength, 0.5, 8.0 );
	mountComponent( wavelengthSlider, window );
	int wavelengthLabel = newTextLabel( 45, 80, 180, 15, "Wavelength: λ (0.5～8)" );
	mountComponent( wavelengthLabel, window );

	// Create a for displaying the amplitude, wavelength, and period.
	infoLabel = newTextLabel( 230, 100, 400, 20, "" );	
	mountComponent( infoLabel, window );
	updateInfoLabel();

	// Create a slider for controling the animation speed.
	speedSlider = newHorizontalSlider( 230, 140, 300, 20, speed, 0.0, 1.0 );
	mountComponent( speedSlider, window );
	int speedLabel = newTextLabel( 45, 140, 180, 15, "Animation Speed" );
	mountComponent( speedLabel, window );

	// Create a button for resetting the time variable.
	resetButton = newButton(600, 125, 150, 40, "Reset Time");
	mountComponent( resetButton, window );

	// Update the displayed contents of the window.
	paintComponent( window );
}


// ================================================================================
// The function for updating the content displayed in the label above the slider.
// ================================================================================

void updateInfoLabel() {
	string infoText
		= "( A="
		+ round(amplitude, 2, HALF_UP)
		+ ", λ="
		+ round(wavelength, 2, HALF_UP)
		+ ", T="
		+ round(period, 2, HALF_UP)
		+ ")";

	setComponentString(infoLabel, infoText);
	paintComponent(infoLabel);
	paintComponent(window);
}


// ================================================================================
// The function which will be invoked when any slider is moved.
// ================================================================================

void onSliderMove(int id, float value) {

	// Update values of the amplitude, period, wavelength, and the animation speed.
	if(id == amplitudeSlider) {
		amplitude = value;
	}
	if(id == periodSlider) {
		period = value;
	}
	if(id == wavelengthSlider) {
		wavelength = value;
	}
	if (id == speedSlider) {
		speed = value;
	}

	// Update the content of the label displaying the above wave parameters.
	updateInfoLabel();
}


// ================================================================================
// The function which will be invoked when any button is clicked.
// ================================================================================

void onButtonClick(int id) {

	// If the reset button is clicked, reset the value of the time variable t.
	if (id == resetButton) {
		t = 0.0;
	}
}


// ================================================================================
// The function which will be invoked when the window is closed.
// ================================================================================

void onWindowClose(int id) {

	// Break the main loop for terminating this program.
	continuesLoop = false;
}


// ================================================================================
// The function which will be invoked when the graph softoware's window is closed.
// ================================================================================

void onGraph2DClose(int id) {

	// Break the main loop for terminating this program.
	continuesLoop = false;
}