coding UTF-8;

import Math;
import Graphics3D;
import graphics3d.Graphics3DFramework;


// Number of grid divisions in X and Y
const int X_N = 16;
const int Y_N = 16;

// Array to store vertex coordinates
float vertex[ Y_N ][ X_N ][ 3 ];

// Variable to store the model ID
int model;

// Time variable for animation
float time = 0.0;

// Amount of time change per frame
float timeStep = 0.1;


// This function is called once after the program starts
void onStart(int renderer){

	// Generate the model using the quadrangle grid format
	model = newModel(vertex, QUADRANGLE_GRID);

	// Set model color (red, green, blue, alpha)
	setModelColor(model, 0, 0, 255, 255);

	// Mount the model
	mountModel(model, renderer);
}


// This function is called continuously, several times per second
void onUpdate(int renderer){

	// Advance the time variable
	time += timeStep;

	// Calculate vertex coordinates
	for(int i=0; i<Y_N; i++){
		for(int j=0; j<X_N; j++){

			float x = j * 0.2;
			float y = i * 0.2;
			float z = 0.2 * ( sin( 2.0*x - time ) + sin( 2.0*y - time ) );

			vertex[ i ][ j ][ 0 ] = x;
			vertex[ i ][ j ][ 1 ] = y;
			vertex[ i ][ j ][ 2 ] = z;

		}
	}

	// Update the model with the new vertex array
	setModelVertex(model, vertex, QUADRANGLE_GRID);
}